intransit/justfile at main · dpassen/intransit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
[default, private]
commands:
    @just --list

# Run unit tests
[group('test')]
test:
    @clojure -X:test

# Watch source code and run tests accordingly
[group('test')]
watch-test:
    @clojure -X:test:watcher

# Lint source code
[parallel, group('dev')]
lint: lint-kondo lint-splint

# Lint source code using clj-kondo
[private, group('dev')]
lint-kondo:
    @rg -tclojure -tedn --files | xargs clj-kondo --parallel --lint

# Lint source code using splint
[private, group('dev')]
lint-splint:
    @clojure -M:splint

# Check for reflection using clj-check
[group('dev')]
check:
    @clojure -M:check

# Check for editorconfig violations using editorconfig-checker
[group('dev')]
editorconfig:
    @editorconfig-checker

# Install locally
[group('release')]
install:
    @clojure -T:build install

# Deploy to Clojars
[group('release')]
publish:
    @clojure -T:build deploy