sakuya/flake.nix at main · debarchito/sakuya · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    inputs@{
      nixpkgs,
      flake-parts,
      rust-overlay,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
      perSystem =
        { system, ... }:
        let
          inherit (nixpkgs) lib;
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ (import rust-overlay) ];
          };
          rustPlatform = pkgs.makeRustPlatform rec {
            cargo = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
            rustc = cargo;
          };
          forLinux = list: lib.optionals (lib.strings.hasInfix "linux" system) list;
        in
        {
          packages = rec {
            sakuya = rustPlatform.buildRustPackage rec {
              name = "sakuya";
              version = "0.1.0";
              src = ./.;
              cargoLock.lockFile = ./Cargo.lock;
              nativeBuildInputs = [
                pkgs.bacon
                pkgs.mold
                pkgs.pkg-config
              ];
              xorgBuildInputs = [
                pkgs.xorg.libX11
                pkgs.xorg.libXcursor
                pkgs.xorg.libXi
              ];
              waylandBuildInputs = [
                pkgs.libxkbcommon
                pkgs.wayland
              ];
              buildInputs =
                forLinux [
                  pkgs.alsa-lib
                  pkgs.udev
                  pkgs.vulkan-loader
                ]
                ++ forLinux xorgBuildInputs
                ++ forLinux waylandBuildInputs;
              LD_LIBRARY_PATH = lib.makeLibraryPath buildInputs;
              RUSTFLAGS = "-Clink-arg=-fuse-ld=mold";
            };
            default = sakuya;
          };
        };
    };
}