nixos/flake.nix at master · codebam/nixos · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
{
  description = "NixOS configuration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable-small";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    # lix = {
    #   url = "git+https://git.lix.systems/lix-project/lix.git";
    #   flake = false;
    # };
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    # lix-module = {
    #   url = "git+https://git.lix.systems/lix-project/nixos-module.git";
    #   inputs.nixpkgs.follows = "nixpkgs";
    #   inputs.lix.follows = "lix";
    # };
    lanzaboote = {
      url = "github:nix-community/lanzaboote";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        rust-overlay.follows = "rust-overlay";
      };
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    agenix.url = "github:ryantm/agenix";
    stylix.url = "github:danth/stylix";
    preservation.url = "github:nix-community/preservation";
    jovian.url = "github:jovian-experiments/jovian-nixos/development";
    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    run0-sudo-shim = {
      url = "github:lordgrimmauld/run0-sudo-shim";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    lsfg-vk-flake = {
      url = "github:pabloaul/lsfg-vk-flake/main";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    # helix = {
    #   url = "github:codebam/helix-steel-flake/main";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
    # steel = {
    #   url = "github:mattwparas/steel/master";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
    # lulu = {
    #   url = "github:kevinJ045/lulu/main";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
    bsav = {
      url = "github:codebam/bsav/main";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    # plasma-manager = {
    #   url = "github:nix-community/plasma-manager";
    #   inputs.nixpkgs.follows = "nixpkgs";
    #   inputs.home-manager.follows = "home-manager";
    # };
    #helix = {
    # url = "github:helix-editor/helix";
    #inputs.nixpkgs.follows = "nixpkgs";
    #};
  };

  outputs =
    inputs@{ nixpkgs, ... }:
    let
      forAllSystems =
        functionProvidedToForAllSystems:
        nixpkgs.lib.genAttrs
          [
            "x86_64-linux"
            "aarch64-linux"
          ]
          (
            system:
            functionProvidedToForAllSystems (
              import nixpkgs {
                inherit system;
                overlays = [
                ];
                config = {
                  # You can add common pkgs configurations here, e.g.:
                  # allowUnfree = true;
                  cudaSupport = false;
                };
              }
            )
          );

      # Helper function to define a NixOS system
      mkNixosSystem =
        { system
        , extraModules ? [ ]
        ,
        }:
        nixpkgs.lib.nixosSystem {
          inherit system;
          # Pass all flake inputs to NixOS modules
          specialArgs = { inherit inputs; };
          modules = [
            # inputs.lix-module.nixosModules.default
            inputs.disko.nixosModules.disko
            inputs.lanzaboote.nixosModules.lanzaboote
            (
              { pkgs, lib, ... }:
              {
                environment.systemPackages = [ pkgs.sbctl ];
                boot.loader.systemd-boot.enable = lib.mkForce false;
                boot.lanzaboote = {
                  enable = true;
                  pkiBundle = "/var/lib/sbctl";
                };
              }
            )
            inputs.preservation.nixosModules.default
            inputs.stylix.nixosModules.stylix
            inputs.agenix.nixosModules.default
            inputs.home-manager.nixosModules.home-manager
            inputs.nix-index-database.nixosModules.nix-index
            inputs.run0-sudo-shim.nixosModules.default
            inputs.lsfg-vk-flake.nixosModules.default
            ./modules
            {
              home-manager = {
                useGlobalPkgs = true;
                useUserPackages = true;
                extraSpecialArgs = { inherit inputs; };
                users.codebam = {
                  imports = [
                    ./home
                  ];
                };
                sharedModules = [
                  inputs.agenix.homeManagerModules.default
                  # inputs.plasma-manager.homeModules.plasma-manager
                ];
              };
            }
          ] ++ extraModules;
        };

    in
    {
      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          buildInputs = with pkgs; [
            nil
            nixd
            nixpkgs-fmt
            # inputs.helix.packages.${stdenv.hostPlatform.system}.default
          ];
        };
      });

      # NixOS configurations
      nixosConfigurations = {
        nixos-desktop = mkNixosSystem {
          system = "x86_64-linux";
          extraModules = [
            # inputs.jovian.nixosModules.default
            ./desktop/configuration
            ./desktop-laptop/configuration
            {
              home-manager.users.codebam.imports = [
                ./desktop/home.nix
                ./desktop-laptop/home.nix
              ];
              home-manager.users.makano.imports = [ ./desktop/makano-home.nix ];
            }
          ];
        };
        nixos-laptop = mkNixosSystem {
          system = "x86_64-linux";
          extraModules = [
            ./laptop/configuration
            ./desktop-laptop/configuration
            {
              home-manager.users.codebam.imports = [
                ./laptop/home.nix
                ./desktop-laptop/home.nix
              ];
            }
          ];
        };
        nixos-steamdeck = mkNixosSystem {
          system = "x86_64-linux";
          extraModules = [
            inputs.jovian.nixosModules.default
            ./steamdeck/configuration
            { home-manager.users.codebam.imports = [ ./steamdeck/home.nix ]; }
          ];
        };
      };
    };
}