refactor: clean up ELP lint warnings across all modules

Use map syntax instead of maps:put/3, wrap macro bodies in parens
to prevent precedence issues, drop the stale -dialyzer nowarn on
handle_headers_complete (dialyzer is fine without it now), swap
maps:find for map pattern matching in flush_stream_send_buffer,
replace maps:to_list comprehension with maps:fold in
flush_all_send_buffers, and strip unused stream_state record
fields (data_buffer, priority, dependency, weight).

Author: codeadict

src/gen_http.erl

@@ -534,7 +534,7 @@ negotiate_protocol(https, Address, Port, Opts, Protocols) ->
     %% Add ALPN to transport options
     TransportOpts = maps:get(transport_opts, Opts, []),
     NewTransportOpts = [{alpn_advertise, AlpnProtocols} | TransportOpts],
-    NewOpts = maps:put(transport_opts, NewTransportOpts, Opts),
+    NewOpts = Opts#{transport_opts => NewTransportOpts},
 
     %% Try HTTP/2 first if in protocol list
     case lists:member(http2, Protocols) of

src/gen_http_h1.erl

@@ -333,7 +333,7 @@ get_socket(#gen_http_h1_conn{socket = Socket}) ->
 %% Attach metadata to connections (e.g., pool ID, metrics, tags).
 -spec put_private(conn(), Key :: term(), Value :: term()) -> conn().
 put_private(#gen_http_h1_conn{private = Private} = Conn, Key, Value) ->
-    Conn#gen_http_h1_conn{private = maps:put(Key, Value, Private)}.
+    Conn#gen_http_h1_conn{private = Private#{Key => Value}}.
 
 %% @doc Get a private value from the connection.
 %%
@@ -699,7 +699,6 @@ parse_headers(Buffer, ReqState, HeadersAcc) ->
             {error, protocol_error(invalid_header)}
     end.
 
--dialyzer({nowarn_function, handle_headers_complete/3}).
 handle_headers_complete(Rest, ReqState, Headers) ->
     HeadersResp = {headers, ReqState#request_state.ref, Headers},
     BodyState = determine_body_state(ReqState#request_state.status, Headers),

src/gen_http_h2.erl

@@ -138,18 +138,12 @@
     recv_window :: non_neg_integer(),
 
     %% Data
-    data_buffer = <<>> :: binary(),
     %% For CONTINUATION frames
     headers_buffer = <<>> :: binary(),
     %% Outbound data waiting for flow control window
     send_buffer = <<>> :: binary(),
     %% Whether END_STREAM should be sent after send_buffer drains
-    send_end_stream = false :: boolean(),
-
-    %% Priority (optional)
-    priority :: non_neg_integer() | undefined,
-    dependency :: stream_id() | undefined,
-    weight :: pos_integer() | undefined
+    send_end_stream = false :: boolean()
 }).
 
 -type conn() :: #gen_http_h2_conn{}.
@@ -424,7 +418,7 @@ get_window_size(Conn, StreamId) ->
 %% Attach metadata to connections (e.g., pool ID, metrics, tags).
 -spec put_private(conn(), Key :: term(), Value :: term()) -> conn().
 put_private(#gen_http_h2_conn{private = Private} = Conn, Key, Value) ->
-    Conn#gen_http_h2_conn{private = maps:put(Key, Value, Private)}.
+    Conn#gen_http_h2_conn{private = Private#{Key => Value}}.
 
 %% @doc Get a private value from the connection.
 %%
@@ -873,7 +867,7 @@ handle_settings_frame(Conn, Flags, Params) ->
             %% Server sent SETTINGS, update and send ACK
             NewRemoteSettings = lists:foldl(
                 fun({Key, Value}, Acc) ->
-                    maps:put(Key, Value, Acc)
+                    Acc#{Key => Value}
                 end,
                 Conn#gen_http_h2_conn.remote_settings,
                 Params
@@ -1109,8 +1103,8 @@ handle_window_update_frame(Conn, StreamId, Increment) ->
 -spec flush_stream_send_buffer(conn(), stream_id()) ->
     {ok, conn(), [h2_response()]}.
 flush_stream_send_buffer(Conn, StreamId) ->
-    case maps:find(StreamId, Conn#gen_http_h2_conn.streams) of
-        {ok, Stream} ->
+    case Conn#gen_http_h2_conn.streams of
+        #{StreamId := Stream} ->
             case Stream#stream_state.send_buffer of
                 <<>> ->
                     {ok, Conn, []};
@@ -1121,19 +1115,24 @@ flush_stream_send_buffer(Conn, StreamId) ->
                     ),
                     {ok, Conn2, []}
             end;
-        error ->
+        _ ->
             {ok, Conn, []}
     end.
 
 %% @doc Flush send buffers for all streams that have pending data.
 -spec flush_all_send_buffers(conn()) ->
     {ok, conn(), [h2_response()]}.
 flush_all_send_buffers(Conn) ->
-    StreamIds = [
-        Id
-     || {Id, S} <- maps:to_list(Conn#gen_http_h2_conn.streams),
-        byte_size(S#stream_state.send_buffer) > 0
-    ],
+    StreamIds = maps:fold(
+        fun(Id, S, Acc) ->
+            case byte_size(S#stream_state.send_buffer) > 0 of
+                true -> [Id | Acc];
+                false -> Acc
+            end
+        end,
+        [],
+        Conn#gen_http_h2_conn.streams
+    ),
     flush_streams(Conn, StreamIds).
 
 -spec flush_streams(conn(), [stream_id()]) -> {ok, conn(), [h2_response()]}.

src/gen_http_parser_h1.erl

@@ -25,8 +25,8 @@
 -type header_name() :: binary().
 -type header_value() :: binary().
 
--define(IS_DIGIT(Val), Val >= $0 andalso Val =< $9).
--define(IS_ALPHA(Val), Val >= $A andalso Val =< $Z orelse Val >= $a andalso Val =< $z).
+-define(IS_DIGIT(Val), (Val >= $0 andalso Val =< $9)).
+-define(IS_ALPHA(Val), ((Val >= $A andalso Val =< $Z) orelse (Val >= $a andalso Val =< $z))).
 -define(IS_HEX(Val),
     (?IS_DIGIT(Val) orelse (Val >= $A andalso Val =< $F) orelse (Val >= $a andalso Val =< $f))
 ).