TCHECK-160 Reduce shrink-int allocation churn

`shrink-int` has LazySeq allocation churn that can be avoided by special casing long values.

This can have a significant impact (in allocations and in run time) because `shrink-int` is used as foundation for `choose`, which in turn is used by many generators.

For example, the following snippet:

(core/let [g (vector (not-empty string-alphanumeric) 1000 5000)]
  (time
   (dotimes [seed 50]
     (dorun (generate g 100 seed)))))

runs ~26% faster (from 22541ms to 16741ms) and allocates ~16% less (from 15.05GB to 12.66GB) after this patch.

Measured on jdk 25 with `-Xmx512m -XX:+UseSerialGC`.

Author: marcobiscaro2112

src/main/clojure/clojure/test/check/generators.cljc

@@ -202,14 +202,40 @@
 ;; Internal Helpers
 ;; ---------------------------------------------------------------------------
 
+#?(:clj
+   (defn- shrink-long
+     [^long x]
+     ; Returns a long array (instead of a lazy seq) to avoid allocation churn.
+     ; The size of returned array is log2(abs(x)), computed from the number
+     ; of significant bits.
+     (core/let [size (- 64 (Long/numberOfLeadingZeros (Math/abs x)))
+                ^longs vals (long-array size)]
+       (loop [i 0 n x]
+         (if (zero? n)
+           vals
+           (do
+             (aset vals i (- x n))
+             (recur (inc i) (quot n 2))))))))
+
 (defn- halfs
   [n]
   (take-while #(not= 0 %) (iterate #(quot % 2) n)))
 
-(defn- shrink-int
+(defn- shrink-big-int
   [integer]
   (core/map #(- integer %) (halfs integer)))
 
+(defn- shrink-int
+  "Given a number x, returns a coll of (x-x, x-x/2, x-x/4, x-x/8, ..., x-1)"
+  [x]
+  #?(:clj
+     (if (<= Long/MIN_VALUE x Long/MAX_VALUE)
+       (shrink-long x)
+       (shrink-big-int x))
+
+     :cljs
+     (shrink-big-int x)))
+
 (defn- int-rose-tree
   [value]
   (rose/make-rose value (core/map int-rose-tree (shrink-int value))))