build.gradle

// 루트 빌드 스크립트: 모든 서브모듈의 공통 설정을 관리함
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.8'
    id 'io.spring.dependency-management' version '1.1.7'
}

bootJar { enabled = false }
jar { enabled = false }

// 중앙 저장소: 모든 모듈이 mavenCentral()에서 의존성을 다운로드함
repositories {
    mavenCentral()
}

// 공통 설정 블록: 모든 하위 모듈(subproject)에 동일하게 적용됨
subprojects {
    group = 'com.rushcrew'
    version = '0.0.1-SNAPSHOT'
    description = 'High-performance Time-Deal Platform handling massive traffic'

// 서브모듈별 플러그인 적용
    apply plugin: 'java'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'

    // 모든 서브모듈이 동일한 Java 버전 사용 (toolchain으로 JVM 일관성 보장)
    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }

    repositories {
        mavenCentral()
        maven { url 'https://jitpack.io' }
    }

    // Spring Cloud BOM (Bill of Materials) 버전 관리용 변수 선언
    ext {
        set('springCloudVersion', "2025.0.0")
    }

    // Spring Cloud 의존성 관리: 모든 서브모듈에서 동일 버전 유지
    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        }
    }
    // 공통 의존성 추가
    dependencies {
        // Lombok (모든 서브모듈 공통)
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        implementation 'io.micrometer:micrometer-tracing-bridge-brave'
        implementation 'io.github.openfeign:feign-micrometer'
        implementation 'io.zipkin.reporter2:zipkin-reporter-brave'

        // prometheus
        implementation 'org.springframework.boot:spring-boot-starter-actuator'
        runtimeOnly 'io.micrometer:micrometer-registry-prometheus'

        // 테스트 시에도 Lombok 사용 가능하도록
        testCompileOnly 'org.projectlombok:lombok'
        testAnnotationProcessor 'org.projectlombok:lombok'
    }
}