terraform-aws-codeartifact/main.tf at main · catalystcommunity/terraform-aws-codeartifact · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
# create optional domain kms encryption key
locals {
  kms_key_description = (
    var.codeartifact_domain_kms_key_description == "" ?
    "domain kms key for ${var.codeartifact_domain_name} domain" :
    var.codeartifact_domain_kms_key_description
  )
}

resource "aws_kms_key" "codeartifact_domain" {
  count       = var.enable_codeartifact_domain_kms_key ? 1 : 0
  description = local.kms_key_description
  tags        = var.tags
}

# create codeartifact domain
locals {
  encryption_key_arn = (
    var.enable_codeartifact_domain_kms_key ?
    one(aws_kms_key.codeartifact_domain[*].arn) :
    var.codeartifact_domain_kms_key_arn
  )
}

resource "aws_codeartifact_domain" "domain" {
  count          = var.enable_codeartifact_domain ? 1 : 0
  domain         = var.codeartifact_domain_name
  encryption_key = local.encryption_key_arn
  tags           = var.tags
}

# create repositories
locals {
  domain = (
    var.enable_codeartifact_domain ?
    one(aws_codeartifact_domain.domain[*].domain) :
    var.codeartifact_domain_name
  )
}

resource "aws_codeartifact_repository" "repository" {
  count       = length(var.codeartifact_repositories)
  repository  = var.codeartifact_repositories[count.index].name
  description = var.codeartifact_repositories[count.index].description
  domain      = local.domain
  tags        = var.tags

  dynamic "external_connections" {
    for_each = var.codeartifact_repositories[count.index].external_connections

    content {
      external_connection_name = external_connections.value.external_connection_name
    }
  }

  dynamic "upstream" {
    for_each = var.codeartifact_repositories[count.index].upstreams != null ? var.codeartifact_repositories[count.index].upstreams : []

    content {
      repository_name = upstream.value.upstream_repository_name
    }
  }
}

# CICD role with access to codeartifact and ecr
data "aws_iam_policy_document" "cicd_codeartifact" {
  count = var.enable_cicd_role ? 1 : 0

  statement {
    actions = [
      "codeartifact:GetAuthorizationToken",
      "codeartifact:GetRepositoryEndpoint",
      "codeartifact:PublishPackageVersion",
      "codeartifact:ReadFromRepository",
    ]
    resources = ["*"]
  }
}

data "aws_iam_policy_document" "cicd_codeartifact_sts" {
  count = var.enable_cicd_role ? 1 : 0

  statement {
    actions = [
      "sts:GetServiceBearerToken",
    ]
    resources = ["*"]

    condition {
      test     = "StringEquals"
      variable = "sts:AWSServiceName"
      values = [
        "codeartifact.amazonaws.com",
      ]
    }
  }
}

data "aws_iam_policy_document" "cicd_ecr" {
  count = var.enable_cicd_role ? 1 : 0

  statement {
    actions = [
      "ecr:BatchCheckLayerAvailability",
      "ecr:BatchGetImage",
      "ecr:CompleteLayerUpload",
      "ecr:CreateRepository",
      "ecr:DescribeImages",
      "ecr:DescribeRepositories",
      "ecr:GetAuthorizationToken",
      "ecr:GetDownloadUrlForLayer",
      "ecr:GetRepositoryPolicy",
      "ecr:InitiateLayerUpload",
      "ecr:ListImages",
      "ecr:PutImage",
      "ecr:SetRepositoryPolicy",
      "ecr:UploadLayerPart",
    ]
    resources = [
      "*"
    ]
  }
}

data "aws_iam_policy_document" "cicd_assume_role_policy" {
  count = var.enable_cicd_role ? 1 : 0

  statement {
    actions = [
      "sts:AssumeRole",
      "sts:TagSession",
    ]

    principals {
      type        = "AWS"
      identifiers = var.cicd_role_trust_arns
    }
  }
}

resource "aws_iam_role" "cicd_role" {
  count = var.enable_cicd_role ? 1 : 0

  name               = var.cicd_role_name
  description        = var.cicd_role_description
  assume_role_policy = data.aws_iam_policy_document.cicd_assume_role_policy[count.index].json
  tags               = var.tags

  inline_policy {
    name   = "cicd-code-artifact"
    policy = data.aws_iam_policy_document.cicd_codeartifact[count.index].json
  }

  inline_policy {
    name   = "cicd-code-artifact-sts"
    policy = data.aws_iam_policy_document.cicd_codeartifact_sts[count.index].json
  }

  inline_policy {
    name   = "cicd-ecr"
    policy = data.aws_iam_policy_document.cicd_ecr[count.index].json
  }
}