telegram-bot-java-api/build.gradle at master · bumann-p/telegram-bot-java-api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
plugins {
    id 'com.jfrog.bintray' version '1.7.3'
    id 'maven-publish'
    id 'java-library'
    id 'jacoco'
    id 'checkstyle'
}

repositories {
    jcenter()
}

dependencies {
	api 'com.squareup.retrofit2:retrofit:2.3.0'

	implementation 'com.jakewharton.retrofit:retrofit2-reactor-adapter:2.1.0'
	implementation 'com.squareup.retrofit2:converter-jackson:2.3.0'
	implementation 'org.projectlombok:lombok:1.16.20'

	testImplementation 'junit:junit:4.12'
	testImplementation 'io.projectreactor:reactor-test:3.1.5.RELEASE'
}

group = 'telegram-bot'
version = '0.1.0-SNAPSHOT'

bintray {
	user = project.hasProperty('bintrayUser') ? project.property('bintrayUser') : System.getenv('BINTRAY_USER')
	key = project.hasProperty('bintrayApiKey') ? project.property('bintrayApiKey') : System.getenv('BINTRAY_API_KEY')
	publications = ['telegram-bot-java-api']
	publish = true
	pkg {
		repo = 'telegram-bot'
		name = 'telegram-bot-java-api'
		licenses = ['EPL-2.0']
		vcsUrl = 'git@github.com:SimonScholz/telegram-bot-java-api.git'
		githubRepo = 'https://github.com/SimonScholz/telegram-bot-java-api'
		publicDownloadNumbers = true
		version {
        	name = "${version}"
        	desc = 'This repo contains java artifacts to implement bot for the telegram messenger'
        	released  = new Date()
        	vcsTag = "${version}"
 	   }
	}
}

// Create the pom configuration:
def pomConfig = {
    licenses {
        license {
            name "Eclipse Public License, Version 2.0"
            url "https://www.eclipse.org/org/documents/epl-2.0/EPL-2.0.txt"
            distribution "repo"
        }
    }
    developers {
        developer {
            id "simon-scholz"
            name "Simon Scholz"
            email "simon.scholz@vogella.com"
        }
    }

    scm {
       url "https://github.com/SimonScholz/telegram-bot-java-api"
    }
}

// Create the publication with the pom configuration:
publishing {
    publications {
        MyPublication(MavenPublication) {
            from components.java
            groupId 'telegram-bot'
            artifactId 'telegram-bot-java-api'
            version "${version}"
            pom.withXml {
                def root = asNode()
                root.appendNode('description', 'This repo contains java artifacts to implement bot for the telegram messenger')
                root.appendNode('name', 'telegram-bot-java-api')
                root.appendNode('url', 'https://github.com/SimonScholz/telegram-bot-java-api')
                root.children().last() + pomConfig
            }
        }
    }
}

// Jacoco and code coverage setup
jacocoTestReport {
    reports {
        xml.enabled true
        html.enabled true
        csv.enabled false
    }
}

check.dependsOn jacocoTestReport

// checkstyle setup
checkstyle {
    configFile file("checkstyle.xml")
}