tmp/meson.build at main · bugdea1er/tmp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
project(
  'tmp',
  'cpp',
  version: '4',
  default_options: ['cpp_std=c++17'],
)

include_directory = include_directories('include')

filesystem_proj = subproject('filesystem')
filesystem_dep = filesystem_proj.get_variable('filesystem_dep')

tmp = library(
  'tmp',
  'src/create_directory.cpp',
  'src/create_file.cpp',
  'src/get_native_handle.cpp',
  'src/remove_all.cpp',
  install: true,
  include_directories: include_directory,
  gnu_symbol_visibility: 'hidden',
  version: meson.project_version(),
  dependencies: [filesystem_dep],
)

tmp_dep = declare_dependency(
  link_with: tmp,
  include_directories: include_directory,
  dependencies: [filesystem_dep],
  version: meson.project_version(),
)

install_headers(
  'include/tmp/directory',
  'include/tmp/file',
  subdir: 'tmp',
)

if not meson.is_subproject()
  if get_option('build_tests')
    subdir('tests')
  endif
  pkg = import('pkgconfig')
  pkg.generate(
    tmp,
    libraries: [filesystem_dep],
    version: meson.project_version(),
    filebase: 'lib' + meson.project_name(),
    description: 'RAII-wrappers for unique temporary files and directories for modern C++',
    url: 'https://github.com/bugdea1er/tmp',
  )
endif