justfile

# ======================================================================================
#
# ░▒▓███████▓▒░░▒▓████████▓▒░▒▓███████▓▒░       ░▒▓███████▓▒░ ░▒▓██████▓▒░▒▓████████▓▒░
# ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░░▒▓█▓▒░ ░▒▓█▓▒░
# ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░░▒▓█▓▒░ ░▒▓█▓▒░
# ░▒▓███████▓▒░░▒▓██████▓▒░ ░▒▓█▓▒░░▒▓█▓▒░      ░▒▓███████▓▒░░▒▓█▓▒░░▒▓█▓▒░ ░▒▓█▓▒░
# ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░░▒▓█▓▒░ ░▒▓█▓▒░
# ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░      ░▒▓█▓▒░░▒▓█▓▒░▒▓█▓▒░░▒▓█▓▒░ ░▒▓█▓▒░
# ░▒▓███████▓▒░░▒▓████████▓▒░▒▓█▓▒░░▒▓█▓▒░      ░▒▓███████▓▒░ ░▒▓██████▓▒░  ░▒▓█▓▒░
#
# ======================================================================================
# Configuration file for the Just command runner: https://github.com/casey/just
# Using Just is optional; even if you don't have it installed, this file serves
# as a convenient reference for this project's most frequently used commands.

set windows-shell := ['cmd.exe', '/c']

[private]
list:
    @{{ just_executable() }} --list --justfile {{ justfile() }}

# Runs pre-commit on all files
[no-exit-message]
pre-commit:
    git add .
    pre-commit run

alias pc := pre-commit

# Installs all development dependencies
install:
    python3 -m pip install -r config/requirements.txt --break-system-packages
    python3 -m pip install -r tests/position-solver/requirements.txt --break-system-packages
    npm install
    pre-commit install --install-hooks

# Updates pre-commit hooks to latest tags
pc-update:
    pre-commit autoupdate -j {{ num_cpus() }}

# Runs garbage collection for git & pre-commit
gc:
    git gc --aggressive --prune
    pre-commit gc

# Bumps version hard-coded in files & creates a new git tag
bump part='major':
    bump-my-version bump --verbose {{ part }}

# Reports codebase size & stats
cloc:
    cloc --exclude-dir=Builds,.venv,logs,node_modules .

# Runs relint to find all linter suppression tokens
[no-exit-message]
relint:
    pre-commit run --hook-stage manual relint --all-files