please/flake.nix at main · auctumnus/please · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
{
  description = "`please` cli";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs =
    inputs@{
      flake-parts,
      nixpkgs,
      rust-overlay,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      perSystem =
        {
          config,
          system,
          ...
        }:
        let
          overlays = [ (import rust-overlay) ];
          pkgs = import nixpkgs {
            inherit system overlays;
          };

          rustToolchain = pkgs.rust-bin.stable.latest.default.override {
            extensions = [
              "rust-src"
              "rust-analyzer"
              "llvm-tools-preview"
            ];
          };

          nativeBuildInputs =
            with pkgs;
            [
              rustToolchain
              pkg-config
            ]
            ++ lib.optionals stdenv.isLinux [
              cargo-llvm-cov
            ];

          buildInputs =
            with pkgs;
            [
              openssl
              postgresql
            ]
            ++ lib.optionals stdenv.isDarwin [
              apple-sdk_11
            ];

        in
        {
          devShells.default = pkgs.mkShell {
            inherit nativeBuildInputs buildInputs;
          };

          packages.default = pkgs.rustPlatform.buildRustPackage {
            pname = "please-cli";
            version = "0.1.0";

            src = ./.;

            cargoLock = {
              lockFile = ./Cargo.lock;
            };

            inherit nativeBuildInputs buildInputs;

            meta = with pkgs.lib; {
              description = "`please` cli";
              license = licenses.mit;
              maintainers = [ ];
            };
          };

          packages.please = config.packages.default;
        };
    };
}