SimplyRESTful-Framework/build.gradle at master · arucard21/SimplyRESTful-Framework · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
plugins{
    id "org.springframework.boot" apply false
    id "com.github.ben-manes.versions"
    id 'jvm-test-suite'
    id 'org.jreleaser'
}

//Shared configuration for all projects (root, library and example projects) including ones with a custom build.gradle
configure(allprojects){
	apply plugin: 'java'
	apply plugin: "eclipse"

	group = 'com.github.arucard21.simplyrestful'
	version = '2.3.0'

	java {
		sourceCompatibility = JavaVersion.VERSION_17
		targetCompatibility = JavaVersion.VERSION_17
	}
}

// Publishing configuration for all library projects (excluding root and example projects)
configure(subprojects - project(":examples").allprojects){
	apply plugin: 'maven-publish'
	apply plugin: 'signing'

	java {
    	withJavadocJar()
    	withSourcesJar()
	}

	publishing{
		publications{
			mavenJava(MavenPublication){
				from components.java
				afterEvaluate {
					pom {
						name = project.name
						packaging = 'jar'
						description = project.description
						url = 'https://github.com/arucard21/SimplyRESTful-Framework'

						scm {
							connection = 'scm:git:git://github.com:arucard21/SimplyRESTful-Framework.git'
							developerConnection = 'scm:git:ssh://github.com:arucard21/SimplyRESTful-Framework.git'
							url = 'https://github.com/arucard21/SimplyRESTful-Framework'
						}

						developers {
							developer {
								name = 'Riaas Mokiem'
								email = 'arucard21@gmail.com'
                                organizationUrl = 'https://github.com/arucard21'
							}
						}
					}
				}
			}
		}
		repositories {
			maven {
				url = layout.buildDirectory.dir('staging-deploy')
			}
		}
	}

	jreleaser {
		signing {
			active = 'ALWAYS'
			armored = true
		}
		deploy {
			maven {
				mavenCentral {
					sonatype {
						active = 'ALWAYS'
						url = 'https://central.sonatype.com/api/v1/publisher'
						stagingRepository('client/build/staging-deploy')
						stagingRepository('deploy-springboot-jersey/build/staging-deploy')
						stagingRepository('fields-filter-json/build/staging-deploy')
						stagingRepository('jaxrs-providers/build/staging-deploy')
						stagingRepository('SimplyRESTful/build/staging-deploy')
						stagingRepository('SimplyRESTful-resources/build/staging-deploy')
						stagingRepository('springdata-paging-offset/build/staging-deploy')
					}
				}
			}
		}
	}
}