angular-flot/angular-flot.coffee at master · arosslau/angular-flot · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
angular.module 'angular-flot', []
    .directive 'flot', ->
        restrict: 'EA'
        template: '<div></div>'
        scope:
            dataset: '='
            options: '='
            callback: '='
        link: (scope, element, attributes) ->
            #
            # Options
            #
            plot = null
            width = attributes.width || '100%'
            height = attributes.height || '100%'

            if not scope.dataset
                scope.dataset = []

            if not scope.options
                scope.options =
                    legend:
                        show: false

            #
            # Setup
            #

            plotArea = $(element.children()[0])

            plotArea.css
                width: width
                height: height

            init = ->
                plotObj = $.plot plotArea, scope.dataset, scope.options
                if scope.callback
                    scope.callback(plotObj);
                plotObj

            #
            # Watches
            #

            onDatasetChanged = (dataset) ->
                if plot
                    plot.setData dataset
                    plot.setupGrid()
                    plot.draw()
                else
                    plot = do init

            scope.$watchCollection 'dataset', onDatasetChanged, true

            onOptionsChanged = ->
                plot = do init

            scope.$watch 'options', onOptionsChanged, true