androidify/settings.gradle.kts at main · android/androidify · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
pluginManagement {
    repositories {
        google {
            content {
                includeGroupByRegex("com\\.android.*")
                includeGroupByRegex("com\\.google.*")
                includeGroupByRegex("androidx.*")
            }
        }
        mavenCentral()
        gradlePluginPortal()
    }
}
dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
        maven {
            url = uri("https://jitpack.io")
            content {
                // This is required to use com.google.android.wearable.watchface.validator
                includeGroup("com.github.xgouchet")
            }
        }
    }
}

plugins {
    val agpVersion = buildscript.sourceFile!!.parentFile.resolve("gradle/libs.versions.toml")
        .readLines().first {
            it.startsWith("agp =")
        }.split("\"")[1]
    id("com.android.settings") version agpVersion
}

android {
    compileSdk {
        version = release(36)
    }
    targetSdk {
        version = release(36)
    }
    minSdk {
        version = release(26)
    }
}

enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")

rootProject.name = "Androidify"

includeBuild("build-plugin")

include(":app")
include(":feature:camera")
include(":feature:creation")
include(":feature:home")
include(":feature:results")
include(":data")
include(":core:network")
include(":core:util")
include(":core:theme")
include(":core:testing")
include(":core:xr")
include(":benchmark")
include(":watchface")
include(":wear")
include(":wear:watchface")
include(":wear:common")