Population.pde

// Akash Yadav
// @Hudson Lane, Delhi
// 26th June 18

// Genetic Algorithm, Evolving Images

// A class to describe a population of virtual organisms
// In this case, each organism is just an instance of a DNA object

class Population {

	float mutationRate;           // Mutation rate
	DNA[] population;             // Array to hold the current population
	ArrayList<DNA> matingPool;    // ArrayList which we will use for our "mating pool"
	PImage target;                // Target phrase
	int generations;              // Number of generations
	boolean finished;             // Are we finished evolving?
	int perfectScore;
  float bestScore; 

	Population(PImage p, float m, int num) {
		target = p;
		mutationRate = m;
		population = new DNA[num];
    bestScore = 0;

		for (int i = 0; i < population.length; i++) 
			population[i] = new DNA(target);
		
		calcFitness();

		matingPool = new ArrayList<DNA>();
		finished = false;
		generations = 0;
		
		perfectScore = 1;
	}

	// Fill our fitness array with a value for every member of the population
	void calcFitness() {
		for (int i = 0; i < population.length; i++)
			population[i].fitness(target);
	}

	// Generate a mating pool
	void naturalSelection() {
		// Clear the ArrayList
		matingPool.clear();

		float maxFitness = 0;

		for (int i = 0; i < population.length; i++)
			if (population[i].fitness > maxFitness)
				maxFitness = population[i].fitness;
		

		// Based on fitness, each member will get added to the mating pool a certain number of times
		// a higher fitness = more entries to mating pool = more likely to be picked as a parent
		// a lower fitness = fewer entries to mating pool = less likely to be picked as a parent
		for (int i = 0; i < population.length; i++) {
			
			float fitness = map(population[i].fitness, 0, maxFitness, 0, 1);

			int n = int(fitness * 100);  // Arbitrary multiplier, we can also use monte carlo method and pick two random numbers
			for (int j = 0; j < n; j++)              
				matingPool.add(population[i]);
		}
	}

	// Create a new generation
	void generate() {
		// Refill the population with children from the mating pool
		for (int i = 0; i < population.length; i++) {

			int a = int(random(matingPool.size()));
			int b = int(random(matingPool.size()));

			DNA partnerA = matingPool.get(a);
			DNA partnerB = matingPool.get(b);

			DNA child = partnerA.crossover(partnerB);
			child.mutate(mutationRate);

			population[i] = child;
		}

		generations++;
	}


	// Compute the current "most fit" member of the population
	PImage getBest() {

		float worldrecord = 0.0;
		int index = 0;

		for (int i = 0; i < population.length; i++) {
			if (population[i].fitness > worldrecord) {
				index = i;
				worldrecord = population[i].fitness;
			}
		}
		
		if (worldrecord == perfectScore ) finished = true;

		return population[index].getImage();
	}

	boolean finished() {
		return finished;
	}

	int getGenerations() {
		return generations;
	}

	// Compute average fitness for the population
	float getAverageFitness() {

		float total = 0;

		for (int i = 0; i < population.length; i++)
			total += population[i].fitness;

		return total / (population.length);
	}

	float getBestFitness(){

		float record = population[0].fitness;

		for (int i = 0; i < population.length; i++)
			if(population[i].fitness > record)
				record = population[i].fitness;
	  
    return record;
  }
  
  float allTimeBest(){
    float record = getBestFitness();
    if(record > bestScore)
      bestScore = record;
    
    return bestScore;
  }
	
}