scafall/settings.gradle.kts at master · WolfyScript/scafall · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
rootProject.name = "scafall"

enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")

dependencyResolutionManagement {
    repositories {
//        mavenLocal()
        maven("https://artifacts.wolfyscript.com/artifactory/gradle-dev")
    }

    versionCatalogs {
        create("sharedLibs") {
            from("com.wolfyscript.scafall:scafall-versions:1.1-SNAPSHOT")
        }
    }
}

pluginManagement {
    repositories {
        gradlePluginPortal()
        mavenCentral()
        mavenLocal()
        maven {
            name = "Fabric"
            url = uri("https://maven.fabricmc.net")
            content {
                includeGroupByRegex("net.fabricmc.*")
                includeGroup("fabric-loom")
            }
        }
        maven {
            name = "Sponge"
            url = uri("https://repo.spongepowered.org/repository/maven-public")
            content {
                includeGroupAndSubgroups("org.spongepowered")
            }
        }
        maven {
            name = "Forge"
            url = uri("https://maven.minecraftforge.net")
            content {
                includeGroupAndSubgroups("net.minecraftforge")
            }
        }
        maven("https://artifacts.wolfyscript.com/artifactory/gradle-dev")
        maven("https://maven.neoforged.net/releases")
    }
}

plugins {
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
}

// Platforms
sequenceOf(
    "core",
    "loader-api",
    "spigotlike",
    "spigot",
    "spigot:spigot-wrappers",
    "paper",
    "fabric",
    "sponge",
    "sponge:loader"
).forEach {
    include(":$it")
    project(":$it").projectDir = file(it.replace(":", "/"))
}

// Sample Plugin Modules
val samplesDir: String = "samples"

fun samplePlugin(root: String, vararg modules: String) {
    println("Samples dir: $samplesDir")
    include(":$samplesDir:$root")
    project(":$samplesDir:$root").projectDir = file("$samplesDir/$root")

    modules.forEach {
        // platform loader project
        include(":$samplesDir:$root:$it")
        project(":$samplesDir:$root:$it").projectDir = file("$samplesDir/$root/${it.replace(":", "/")}")
    }
}

samplePlugin("multi-platform-plugin", "common", "spigot", "spigot:loader", "sponge", "sponge:loader")
samplePlugin("single-platform-plugin", "spigot")