droid-manager/lib.nix at main · WiiPlayer2/droid-manager · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
{ lib, inputs, ... }:
{
  flake.lib.droidManagerConfiguration =
    { deviceSystem
    , hostSystem ? "x86_64-linux" # Assuming x64 by default due to it being the most probably answer and also most likely to work compiling on
    , modules
    , isRooted ? false
    }:
    let
      inherit (lib)
        evalModules;

      configured-nixpkgs = system: import inputs.nixpkgs {
        inherit system;
        overlays = [
          (final: prev: {
            # android-sdk = inputs.android-nixpkgs.${prev.system}.
            make-wrapper = inputs.make-wrapper.packages.${prev.system}.make-wrapper;
            proot-static = prev.callPackage ./pkgs/proot-static.nix { inherit inputs; };
          })
        ];
        config = {
          android_sdk.accept_license = true;
        };
      };

      evaluatedModules = evalModules {
        modules = [
          ./modules
          {
            build.activation.enableRoot = isRooted;
          }
        ] ++ modules;
        specialArgs = {
          inherit inputs;
          pkgs = configured-nixpkgs deviceSystem;
          hostPkgs = configured-nixpkgs hostSystem;
          apks = inputs.self.androidApps.${deviceSystem};
        };
      };
      activationPackage = evaluatedModules.config.build.activationPackage;
    in
      activationPackage;
}