MoreBees/build.gradle at main · Traqueur-dev/MoreBees · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
plugins {
    id 'java'
    id("xyz.jpenilla.run-paper") version "2.3.1"
    id("com.gradleup.shadow") version "9.0.0-beta10"
    id("re.alwyn974.groupez.repository") version "1.0.0"
}

group = 'fr.traqueur'

project.ext {
    targetFolder = file("target")
    apiFolder = file("target-api")
    libraries = []
}

allprojects { proj ->
    version = rootProject.property('version')

    apply plugin: "idea"
    apply from: rootProject.file('gradle/add-library-dependency.gradle')
    apply plugin: 'java'
    apply plugin: 'com.gradleup.shadow'
    apply plugin: 're.alwyn974.groupez.repository'

    repositories {
        mavenCentral()
        maven {
            name = "papermc-repo"
            url = "https://repo.papermc.io/repository/maven-public/"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/groups/public/"
        }
        maven { url = "https://jitpack.io" }
        maven { url = "https://mvn.lumine.io/repository/maven-public/" }
    }

    dependencies {
        compileOnly("io.papermc.paper:paper-api:1.21.4-R0.1-SNAPSHOT")
    }

    afterEvaluate {
        addLibraryDependency(proj, "fr.traqueur.commands:platform-spigot:5.0.2")
        addLibraryDependency(proj, "fr.traqueur.commands:core:5.0.2")
        addLibraryDependency(proj, "com.github.Traqueur-dev:RecipesAPI:3.1.1")
        addLibraryDependency(proj, "fr.traqueur:structura:1.6.0")
    }

    def targetJavaVersion = 21
    java {
        def javaVersion = JavaVersion.toVersion(targetJavaVersion)
        sourceCompatibility = javaVersion
        targetCompatibility = javaVersion
        if (JavaVersion.current() < javaVersion) {
            toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
        }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'

        if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
            options.release.set(targetJavaVersion)
        }
    }

    build {
        dependsOn shadowJar
    }

    shadowJar {
        archiveBaseName.set(rootProject.name)
        archiveVersion.set(rootProject.version)
        archiveClassifier.set('')
    }
}

repositories {
    maven { url = "https://maven.devs.beer/" }
    maven {url = "https://repo.oraxen.com/releases" }
    maven {url = "https://repo.nexomc.com/releases" }
}

dependencies {
    implementation(project(":api"))
    implementation("org.bstats:bstats-bukkit:3.1.0")

    compileOnly("com.ticxo.modelengine:ModelEngine:R4.0.8")
    compileOnly("dev.lone:api-itemsadder:4.0.10")
    compileOnly("io.th0rgal:oraxen:1.191.0")
    compileOnly("com.nexomc:nexo:1.9.0")
}

shadowJar {
    destinationDirectory.set(rootProject.targetFolder)
    relocate("org.bstats", "fr.traqueur.morebees.libs.bstats")
}

tasks {
    runServer {
        minecraftVersion("1.21.4")
    }
}

tasks.register("cleanTarget") {
    doLast {
        delete rootProject.targetFolder
        delete rootProject.apiFolder
    }
}

tasks.named("clean") {
    dependsOn "cleanTarget"
}

processResources {
    filteringCharset = 'UTF-8'

    doFirst {
        filesMatching('plugin.yml') {
            expand(
                    name: rootProject.name,
                    version: version,
                    libraries: "\n" + (rootProject.ext.libraries ?: []).collect { "  - \"$it\"" }.join("\n")
            )
        }
    }
}