multiply_test/tests/mult30.a at main · TobyLobster/multiply_test · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
; mult30.a
; 'tepples unrolled' from https://www.nesdev.org/wiki/8-bit_Multiply
; adjusted to not need to treat zero as a special case and decrement factor2,
;   helping both average cycles and bytes used.
;
; 8 bit x 8 bit unsigned multiply, 16 bit result
; Average cycles: 111.62
; 70 bytes


prodlo  = $02
factor2 = $03

* = $0200

; ***************************************************************************************
; On Entry:
;   A: multiplier
;   Y: multiplicand
; On Exit:
;   A: low byte of product
;   Y: high byte of product
mult
    lsr
    sta prodlo
    sty factor2
    lda #0

    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    ror prodlo
    bcc +
    clc
    adc factor2
+
    ror
    tay
    lda prodlo
    ror
    rts