Novaconomy/settings.gradle.kts at master · Team-Inceptus/Novaconomy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
rootProject.name = "Novaconomy"

include(":novaconomy")
project(":novaconomy").projectDir = rootDir.resolve("plugin")

include(":novaconomy-abstract")
project(":novaconomy-abstract").projectDir = rootDir.resolve("abstraction")

listOf("api", "adventure").forEach {
    include(":novaconomy-$it")
    project(":novaconomy-$it").projectDir = rootDir.resolve(it)
}

if (JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_17)) {
    include(":novaconomy-folia")
    project(":novaconomy-folia").projectDir = rootDir.resolve("folia")
}

mapOf(
    "1_8_R1" to 8,
    "1_8_R2" to 8,
    "1_8_R3" to 8,
    "1_9_R1" to 8,
    "1_9_R2" to 8,
    "1_10_R1" to 8,
    "1_11_R1" to 8,
    "1_12_R1" to 8,
    "1_13_R1" to 8,
    "1_13_R2" to 8,
    "1_14_R1" to 8,
    "1_15_R1" to 8,
    "1_16_R1" to 8,
    "1_16_R2" to 8,
    "1_16_R3" to 8,
    "1_17_R1" to 16,
    "1_18_R1" to 17,
    "1_18_R2" to 17,
    "1_19_R1" to 17,
    "1_19_R2" to 17,
    "1_19_R3" to 17,
    "1_20_R1" to 17,
    "1_20_R2" to 17,
    "1_20_R3" to 17,
    "1_20_R4" to 21
).forEach {
    val id = it.key
    val minJava = it.value

    if (JavaVersion.current().isCompatibleWith(JavaVersion.toVersion(minJava))) {
        include(":novaconomy-$id")
        project(":novaconomy-$id").projectDir = rootDir.resolve("nms/$id")
    }
}