bin2shellcode/CMakeLists.txt at master · T1erno/bin2shellcode · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
cmake_minimum_required(VERSION 3.10)

# Project name, version and language
project(
  bin2shellcode
  VERSION 1.0.0
  LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

add_compile_options(-Wall -Werror -Wpedantic)

add_library(bin2shellcode_lib STATIC src/converter/converter.cpp)
set_target_properties(bin2shellcode_lib PROPERTIES OUTPUT_NAME "bin2shellcode")

target_include_directories(
  bin2shellcode_lib
  PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
         $<INSTALL_INTERFACE:include>)

add_executable(${PROJECT_NAME} src/main.cpp)
target_link_libraries(${PROJECT_NAME} PRIVATE bin2shellcode_lib)
target_compile_definitions(${PROJECT_NAME}
                           PRIVATE B2S_VERSION="${PROJECT_VERSION}")

# Installation
install(
  TARGETS ${PROJECT_NAME} bin2shellcode_lib
  RUNTIME DESTINATION bin
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib)

install(DIRECTORY include/ DESTINATION include)

install(FILES README.md LICENSE DESTINATION share/${PROJECT_NAME})

# Cross-platform packaging with CPack
set(CPACK_PACKAGE_NAME ${PROJECT_NAME})
set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})

# .deb Package stuff
set(CPACK_PACKAGE_CONTACT "Erick Sánchez Vera <Erickdeveloper2000@outlook.com>")
set(CPACK_DEBIAN_PACKAGE_DEPENDS " ")
set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "amd64")

# Generator: ZIP on Windows, TGZ on other systems
if(WIN32)
  set(CPACK_GENERATOR "ZIP")
else()
  set(CPACK_GENERATOR "STGZ;TGZ;TZ;DEB")
endif()
# Final package name: bin2shellcode-x.x.x-Linux/TGZ or .zip
set(CPACK_PACKAGE_FILE_NAME
    "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CMAKE_SYSTEM_NAME}")

include(CPack)

# Target for uninstall
configure_file(
  "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
  "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake" IMMEDIATE @ONLY)
add_custom_target(
  uninstall
  COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake
  COMMENT "Uninstalling ${PROJECT_NAME}")

# Target to completely clean the build directory
add_custom_target(
  clean-build
  COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_DIR}
  COMMENT "Removing build directory")

find_program(CLANG_FORMAT clang-format)
file(GLOB_RECURSE ALL_SRC CONFIGURE_DEPENDS "${PROJECT_SOURCE_DIR}/*.[ch]pp"
     "${PROJECT_SOURCE_DIR}/*.[ch]xx")

add_custom_target(
  clang-format
  COMMAND ${CLANG_FORMAT} -i -style=file ${ALL_SRC}
  WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  COMMENT "Running clang-format on source files")

find_program(CMAKE_FORMAT_BIN NAMES cmake-format REQUIRED)

file(
  GLOB_RECURSE
  CMAKE_FORMAT_FILES
  CONFIGURE_DEPENDS
  "${PROJECT_SOURCE_DIR}/CMakeLists.txt"
  "${PROJECT_SOURCE_DIR}/*/CMakeLists.txt"
  "${PROJECT_SOURCE_DIR}/*.cmake"
  "${PROJECT_SOURCE_DIR}/*.cmake.in")

add_custom_target(
  cmake-format
  COMMAND ${CMAKE_FORMAT_BIN} -i ${CMAKE_FORMAT_FILES}
  WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  COMMENT "Formateando scripts CMake con cmake-format"
  VERBATIM)

# Automated tests
enable_testing()
add_executable(test_converter tests/test_converter.cpp)
target_link_libraries(test_converter PRIVATE bin2shellcode_lib)
target_compile_definitions(
  test_converter PRIVATE TEST_DATA_DIR="${CMAKE_CURRENT_SOURCE_DIR}/tests")

# Name of each test format
set(FORMAT_NAMES
    Raw
    Base64
    C
    Ruby
    Python
    PowerShell
    CSharp
    Hex
    UUID
    Go
    Rust)

foreach(idx RANGE 0 10)
  math(EXPR arg "${idx}+1")
  list(GET FORMAT_NAMES ${idx} fmtName)
  add_test(NAME ${fmtName} COMMAND test_converter ${arg})
endforeach()