flake/flake.shells.nix at main · Stzx/flake · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
{ pkgs, ... }:

let
  inherit (pkgs)
    lib

    mkShell
    mkShellNoCC
    ;

  mkLLVMShell = mkShell.override {
    stdenv = pkgs.overrideCC pkgs.clangStdenv (
      pkgs.clangStdenv.cc.override {
        inherit (pkgs.llvmPackages) bintools;
      }
    );
  };

  default' = {
    packages = with pkgs; [
      nix-init
      nix-diff
      nix-tree

      nil
      taplo

      qt6Packages.qtdeclarative

      nixfmt

      treefmt

      sops
    ];
  };

  mirror' = {
    RUSTUP_DIST_SERVER = "https://mirrors.cernet.edu.cn/rustup";
    RUSTUP_UPDATE_ROOT = "https://mirrors.cernet.edu.cn/rustup/rustup";

    PUB_HOSTED_URL = "https://pub.flutter-io.cn";
    FLUTTER_STORAGE_BASE_URL = "https://storage.flutter-io.cn";

    NIX_NPM_REGISTRY = "https://r.cnpmjs.org/";

    no_proxy = "127.0.0.1,::1,localhost,cn";
  };
in
{
  default = mkShellNoCC (default' // mirror');

  # rustup + binstall + frb
  frb = mkShell (
    rec {
      packages = with pkgs; [
        rustup

        flutter
      ];

      buildInputs = with pkgs; [
        vulkan-loader

        wayland

        libxkbcommon
      ];

      shellHook = ''
        export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${builtins.toString (lib.makeLibraryPath buildInputs)}"
      '';
    }
    // mirror'
  );

  java = mkShellNoCC {
    packages = with pkgs; [
      temurin-bin

      python3
    ];
  };

  wrt = mkShell (
    {
      packages = with pkgs; [
        wget
        unzip
        uftpd
        # minicom # prefer wezterm serial

        binwalk
        ubootTools
        mtk-uartboot

        git

        pkg-config

        (python3.withPackages (ps: [ ps.setuptools ]))

        swig
      ];

      buildInputs = [ pkgs.ncurses ];

      hardeningDisable = [ "all" ];
    }
    // mirror'
  );

  latex = mkShellNoCC {
    packages = with pkgs; [
      texlab

      (texliveSmall.withPackages (
        ps: with ps; [
          roboto
          sourcesanspro
          fontawesome5
          fandol

          ctex
          enumitem
          tcolorbox
          tikzfill
          ifmtarg
          xifthen
          xstring
        ]
      ))
    ];
  };

  media = mkShellNoCC {
    packages = with pkgs; [
      flac
      alac

      exiftool
      mediainfo
    ];
  };

  misc = mkShellNoCC {
    packages = with pkgs; [
      read-edid
      fontpreview

      unrar
    ];
  };

  kernel = mkLLVMShell {
    packages = with pkgs; [
      git

      dracut
    ];

    nativeBuildInputs = with pkgs; [
      bison
      flex
      pahole
      rustc-unwrapped
      rust-bindgen-unwrapped

      pkg-config
    ];

    buildInputs = [ pkgs.ncurses ];

    shellHook = ''
      export ARCH="$(uname --machine)" \
      && export LLVM=1 \
      && git fetch --depth=1 origin tag "$(uname --kernel-release)" \
      && git checkout "tags/$(uname --kernel-release)" \
      && (make helpnewconfig | less -F)
    '';
  };
}