zappy/flake.nix at dev · Sigmapitech/zappy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    pre-commit-hooks,
  }: let
    forAllSystems = function:
      nixpkgs.lib.genAttrs [
        "x86_64-linux"
      ] (system: function nixpkgs.legacyPackages.${system});
  in {
    devShells = forAllSystems (pkgs: {
      default = let
        pyenv = pkgs.python313.withPackages (p:
          with p; [
            black
            mypy
            isort
            vulture

            pytest
            pytest-cov
          ]);
      in
        pkgs.mkShell {
          inherit (self.checks.${pkgs.system}.pre-commit-check) shellHook;

          env = {
            IMGUI_DIR = pkgs.imgui.src;
            MAKEFLAGS = "-j";
            LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath (with pkgs; [
              mesa
            ]);
          };

          hardeningDisable = ["fortify"];
          inputsFrom = with self.packages.${pkgs.system}; [
            ai
            gui
            server
            doc
          ];

          packages =
            (with pkgs; [
              clang-tools
              compiledb
              gcovr
              hl-log-viewer
              pkg-config
              SDL2
              SDL2_image
              libGL
              libGLU
              glew
              glm
              doxygen
              graphviz
              pyenv
              valgrind
              libsForQt5.kcachegrind
              xorg.libX11
            ])
            ++ (with self.packages.${pkgs.system}; [
              cpp-fmt
            ]);
        };
    });

    formatter = forAllSystems (pkgs: pkgs.alejandra);

    checks = forAllSystems (
      pkgs: {
        pre-commit-check = pre-commit-hooks.lib.${pkgs.system}.run {
          hooks = import ./nix/pre-commit-hooks.nix {inherit self pkgs;};
          src = ./.;
        };
      }
    );

    packages = forAllSystems (
      pkgs: let
        pypkgs = pkgs.python313.pkgs;
        pkgs' = self.packages.${pkgs.system};
      in
        {
          ai = pypkgs.callPackage ./nix/zappy-ai.nix {};

          gui = pypkgs.callPackage ./nix/zappy-gui.nix {};

          server = pypkgs.callPackage ./nix/zappy-server.nix {};

          server-debug = pkgs'.server.override {debugServer = true;};

          runner = pypkgs.callPackage ./nix/runner.nix {
            inherit (pkgs') bleach;
          };

          default = pkgs.symlinkJoin {
            name = "zappy";
            paths = with pkgs'; [
              runner
              server
              gui
              ai
              ref
            ];

            meta.mainProgram = "zappy";
          };

          bleach = pkgs.callPackage ./nix/bleach.nix {};
        }
        // {
          ref-gui = pkgs.callPackage ./nix/ref-gui.nix {};

          ref-server = pkgs.callPackage ./nix/ref-server.nix {};

          ref = pkgs.symlinkJoin {
            name = "ref";
            paths = with pkgs'; [
              ref-gui
              ref-server
            ];
          };
        }
        // {
          cpp-fmt = pkgs.writeShellScriptBin "cpp-fmt" ''
            find . -type f -name "*.cpp" -or -name "*.hpp" \
              | grep -v "gui/imgui" \
              | xargs clang-format -i --verbose
          '';

          exhale = pypkgs.callPackage ./nix/exhale.nix {};

          doc = pkgs.callPackage ./nix/doc.nix {
            inherit (pkgs') exhale;
          };
        }
    );
  };
}