void/flake.nix at main · Sigmapitech/void · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";
    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    git-hooks,
  }: let
    inherit (nixpkgs) lib;

    genSystems = lib.genAttrs ["x86_64-linux"];

    eachSystem = f:
      genSystems
      (system: f nixpkgs.legacyPackages.${system});

    eachSystem' = f:
      genSystems
      (system: f self.shared.${system});
  in {
    checks = eachSystem' (
      {
        pkgs,
        haskell,
      }: {
        pre-commit-check = git-hooks.lib.${pkgs.system}.run {
          src = ./.;
          hooks =
            {
              commit-name = {
                enable = true;
                name = "commit name";
                stages = ["commit-msg"];
                entry = ''
                  ${pkgs.python310.interpreter} ${./scripts/apply-commit-convention.py}
                '';
              };
            }
            // (lib.genAttrs [
                "alejandra"
                "cabal-fmt"
                "ormolu"
                "hlint"
              ] (x: {
                enable = true;
                package = lib.getBin (haskell.${x} or pkgs.${x});
              }));
        };
      }
    );

    formatter = eachSystem (pkgs: pkgs.alejandra);

    devShells = eachSystem' ({
      pkgs,
      haskell,
    }: {
      default = pkgs.mkShell {
        inherit (self.checks.${pkgs.system}.pre-commit-check) shellHook;

        packages = with pkgs;
          [
            chez
            curl
            jq
          ]
          ++ self.checks.${pkgs.system}.pre-commit-check.enabledPackages
          ++ (with haskell; [
            cabal-install

            (ghcWithPackages (p: [
              Cabal
              Cabal-syntax
              aeson
              bytestring
              containers
              hspec
              hspec-expectations
              megaparsec
              optparse-applicative
              parsec
              parsec
              pretty-simple
              regex-tdfa
              silently
            ]))
          ]);
      };
    });

    shared = eachSystem (pkgs: {
      inherit pkgs;

      haskell = pkgs.haskell.packages.ghc984;
    });
  };
}