build.gradle

plugins {
    id("java")
    id("antlr")
}

group = "de.lukaspanneke.masterthesis"
version = "0.1-dev"

java {
    sourceCompatibility = "17"
    targetCompatibility = "17"
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'info.picocli:picocli:4.7.5' // https://github.com/remkop/picocli
    implementation 'org.antlr:antlr4-runtime:4.13.1' // https://github.com/antlr/antlr4
    antlr 'org.antlr:antlr4:4.13.1'
    testImplementation("org.junit.jupiter:junit-jupiter:5.10.2") // https://github.com/junit-team/junit5
    testRuntimeOnly('org.junit.platform:junit-platform-launcher:1.10.2')
    implementation(files("lib/cvc5.jar")) // https://github.com/cvc5/cvc5/
    implementation(files("lib/com.microsoft.z3.jar")) // https://github.com/Z3Prover/z3
}

tasks.register('buildExecutableApp', Jar) {
    manifest {
        attributes('Main-Class': 'de.lukaspanneke.masterthesis.ui.Main')
    }
    archiveBaseName = "color-unfolder-with-dependencies"
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
    with jar
}

generateGrammarSource {
    maxHeapSize = '64m'
    arguments += ['-visitor', '-listener', '-long-messages']
}

tasks.test {
    maxHeapSize = "8g"
    systemProperty(
            "java.library.path",
            "./lib/"
    )
    environment "LD_LIBRARY_PATH", "lib"
}

tasks.test {
    useJUnitPlatform()
}