sandbox-cli/flake.nix at main · Security-Experts-Community/sandbox-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
{
  description = "Command line tool for interaction with sandboxes";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";

    pyproject-nix = {
      url = "github:nix-community/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    ptsandbox = {
      url = "github:Security-Experts-Community/py-ptsandbox";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.flake-utils.follows = "flake-utils";
    };
  };

  outputs = {
    self,
    nixpkgs,
    pyproject-nix,
    flake-utils,
    ptsandbox,
    ...
  }: let
    outputs = flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};

        python = pkgs.python3.override {
          packageOverrides = self: super: {
            ptsandbox = ptsandbox.packages.${system}.py-ptsandbox;
          };
        };

        project = pyproject-nix.lib.project.loadUVPyproject {
          projectRoot = ./.;
        };

        projectAttrsForApp = project.renderers.buildPythonPackage {inherit python;};
        projectAttrsForEnv = project.renderers.withPackages {inherit python;};
        projectEnv = python.withPackages projectAttrsForEnv;
      in {
        packages = {
          sandbox-cli = python.pkgs.buildPythonApplication (projectAttrsForApp // {});
          default = self.packages.${system}.sandbox-cli;
        };

        devShells.default = pkgs.mkShell {
          packages = [
            projectEnv
          ];

          shellHook = ''
            unlink .nix-venv; ln -s ${projectEnv} ./.nix-venv
          '';
        };
      }
    );
  in
    outputs
    // {
      homeManagerModules = {
        sandbox-cli = import ./modules self;
        default = self.homeManagerModules.sandbox-cli;
      };

      overlays.default = final: prev: {
        sandbox-cli = self.packages.${prev.system}.sandbox-cli;
      };
    };
}