openapi-generation/build.gradle at master · Romanow/openapi-generation · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
plugins {
    id "idea"
    id "java"
    id "org.jetbrains.kotlin.jvm" version "1.9.22"
    id "org.jetbrains.kotlin.plugin.jpa" version "1.9.22" apply false
    id "org.jetbrains.kotlin.plugin.spring" version "1.9.22" apply false
    id "org.jlleitschuh.gradle.ktlint" version "12.1.1" apply false
    id "org.springframework.boot" version "3.2.8" apply false
    id "io.spring.dependency-management" version "1.1.0"
    id "org.openapi.generator" version "7.8.0" apply false
    id "com.gorylenko.gradle-git-properties" version "2.4.1"
}

ext {
    springBootVersion = "3.2.8"
    springShellVersion = "3.2.3"
    openApiVersion = "2.1.0"
    openApiToolsVersion = "0.2.6"
    jakartaAnnotationsVersion = "2.1.1"
    restAssuredVersion = "5.4.0"
    postgresContainerVersion = "1.20.1"
}

allprojects { ->
    apply plugin: "idea"
    apply plugin: "java"
    apply plugin: "kotlin"
    apply plugin: "org.jlleitschuh.gradle.ktlint"
    apply plugin: "io.spring.dependency-management"

    idea {
        module {
            downloadJavadoc = true
            downloadSources = true
        }
    }

    [compileKotlin, compileTestKotlin]*.kotlinOptions*.jvmTarget = "17"

    repositories {
        mavenCentral()
    }

    ktlint {
        version.set("1.2.1")
        filter {
            exclude { entry -> entry.file.toString().contains("generated") }
        }
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:$springBootVersion"
            mavenBom "org.springframework.shell:spring-shell-dependencies:$springShellVersion"
        }
    }

    dependencies {
        implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
        implementation "org.jetbrains.kotlin:kotlin-reflect"
        implementation "com.fasterxml.jackson.module:jackson-module-kotlin"
    }

    test {
        useJUnitPlatform()
        testLogging {
            showStandardStreams = true
        }
    }

    processResources {
        filesMatching(["**/properties-from-gradle.properties"]) {
            expand(project.properties)
        }
    }
}