build.gradle

plugins {
    id "idea"
    id "java"
    id "application"
}

ext {
    lombokVersion = "1.18.34"
}

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

repositories {
    mavenCentral()
}

dependencies {
    compileOnly "org.projectlombok:lombok:$lombokVersion"
    annotationProcessor "org.projectlombok:lombok:$lombokVersion"
}

project.configurations.implementation.setCanBeResolved(true)

abstract class ApplicationRunner extends JavaExec {
    ApplicationRunner() {
        description = "Application runner"
        group = "application"

        classpath = project.sourceSets.main.runtimeClasspath
        standardInput = System.in
        jvmArgs = ["-Xms32m", "-Xmx32m",
                   "-verbose:gc",
                   "-agentlib:jdwp=transport=dt_socket,server=y,suspend=n,address=127.0.0.1:8008",
                   "-Dcom.sun.management.jmxremote",
                   "-Dcom.sun.management.jmxremote.port=9091",
                   "-Dcom.sun.management.jmxremote.authenticate=false",
                   "-Dcom.sun.management.jmxremote.ssl=false "]
    }
}

tasks.register("runStaticResourcesExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.StaticResourcesExample"
}

tasks.register("runStaticResourcesWeakReferenceExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.StaticResourcesWeakReferenceExample"
}

tasks.register("runEqualsAndHashCodeExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.EqualsAndHashCodeExample"
}

tasks.register("runNonStaticInnerClassExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.NonStaticInnerClassExample"
}

tasks.register("runThreadLocalExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.ThreadLocalExample"
}

tasks.register("runCustomClassLoaderExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.CustomClassLoaderExample"
}

tasks.register("runInternalStringsExample", ApplicationRunner) {
    mainClass = "ru.romanow.memory.leaks.InternalStringsExample"
}

jar {
    enabled = false
}