clover/flake.nix at main · Reboot-Codes/clover · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    crane.url = "github:ipetkov/crane";
    fenix.url = "github:nix-community/fenix";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      ...
    }@inputs:
    let
      fenix = inputs.fenix.packages;
    in
    # Iterate over Arm, x86 for macOS and Linux
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        crane = inputs.crane.mkLib pkgs;
        # Toolchain
        toolchain = fenix.${system}.fromToolchainFile {
          file = ./rust-toolchain.toml;
          sha256 = "sha256-TpJxH//QHhdKvCQEf8XbrliwFhqu5lETkU1w99HZ/+4=";
        };
        craneLib = crane.overrideToolchain toolchain;

        # Deps for all software packages
        buildInputs = with pkgs; [
          openssl.dev
          pkg-config
          wayland
        ];

        src = pkgs.lib.cleanSourceWith {
          src = craneLib.path ./.;
          filter = path: type: (pkgs.lib.hasInfix "/assets" path) || (craneLib.filterCargoSources path type);
        };
        commonArgs = {
          doCheck = false;
          inherit src buildInputs;
          nativeBuildInputs = libraries;
        };

        libraries = with pkgs; [
          openssl
          pkg-config
          vulkan-loader
          libxkbcommon
          wayland
          xorg.libX11
          xorg.libxcb
          alsa-lib
          udev
          vulkan-loader
          xorg.libX11
          xorg.libXrandr
          xorg.libXcursor
          xorg.libXi
          at-spi2-atk
          atkmm
          cairo
          gdk-pixbuf
          glib
          gtk3
          harfbuzz
          librsvg
          libsoup_3
          pango
          webkitgtk_4_1
          fontconfig
          libz
        ];
        # Compile all artifacts
        appDeps = craneLib.buildDepsOnly commonArgs;

        appListings = [
          {
            name = "clover-hub";
            path = ./clover-hub/Cargo.toml;
          }
          {
            name = "ratchet";
            path = ./toolbox/ratchet/Cargo.toml;
          }
        ];

        # Compile
        pkg =
          listing:
          craneLib.buildPackage (
            commonArgs
            // {
              cargoExtraArgs = "-p ${listing.name}";
              cargoArtifacts = appDeps;
              pname = listing.name;
              version = (builtins.fromTOML (builtins.readFile listing.path)).package.version;
            }
          );
        app =
          listing:
          flake-utils.lib.mkApp {
            drv = pkg listing;
          };
      in
      {
        # nix build
        packages = {
          default = pkg (builtins.elemAt appListings 0);
        }
        // builtins.listToAttrs (
          map (listing: {
            name = listing.name;
            value = pkg listing;
          }) appListings
        );

        # nix run
        apps = {
          default = app (builtins.elemAt appListings 0);
        }
        // builtins.listToAttrs (
          map (listing: {
            name = listing.name;
            value = app listing;
          }) appListings
        );

        # nix develop
        devShells.default = craneLib.devShell {
          inherit buildInputs;

          packages = [
            toolchain
          ]
          ++ (with pkgs; [
            nodejs_22
            yarn-berry
            rust-analyzer
            tokio-console
          ])
          ++ libraries;

          LD_LIBRARY_PATH = "${pkgs.lib.makeLibraryPath libraries}";
        };
      }
    ));
}