statuspage/flake.nix at main · PluralKit/statuspage · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        backend = pkgs.buildGoModule {
          pname = "pluralkit-status-backend";
          version = self.shortRev or "dirty";
          src = ./backend;
          vendorHash = "sha256-Hls0A3Bq9BlAw+nknihmkrK+taQLhwzdMnpn9wwP7PQ=";
        };

        frontend = pkgs.buildNpmPackage {
          pname = "pluralkit-status-frontend";
          version = self.shortRev or "dirty";
          src = ./frontend;

          npmDepsHash = "sha256-IGk6+vY6xZUV4j/FQAF4umbG0vmzveUTMV9BmGQCHwE=";
          npmBuildCommand = "run build";
          env = {
            GIT_COMMIT = self.shortRev or "dirty";
          };
          installPhase = ''
            runHook preInstall
            cp -r build $out
            runHook postInstall
          '';
        };
      in
      with pkgs;
      {
        packages = {
          pluralkit-status-backend = backend;
          pluralkit-status-frontend = frontend;
        };
        devShells.default = mkShell {
          buildInputs = [
            pkgs.gnumake
            pkgs.go
            pkgs.nodejs_24
            pkgs.golangci-lint
          ];
        };
      }
    );
}