default.nix

{ pkgs ? import <nixpkgs> {}, ... }: let
  inherit (pkgs.lib.attrsets) mapAttrs' nameValuePair filterAttrs optionalAttrs;
  inherit (pkgs.lib.strings) removeSuffix hasPrefix hasSuffix;
  inherit (pkgs.lib) pathExists;
  inherit (builtins) readDir;
  tryEval' = builtins.tryEval;

  /* Import all files ending in .nix (excluding default.nix) and directories
  */
  importFromDir = {
    description = ''
      Non-recursively import all files ending in .nix (excluding default.nix)
      and directories containing a default.nix.
      This does not import files or directories beginning with `.`
    '';
    __functor = _: d: a: mapAttrs' (n: _: nameValuePair
      (removeSuffix ".nix" n)
      (import (d + "/${n}") a)
    )
    (filterAttrs (n': v:
      !(hasPrefix "." n')
        && n' != "default.nix"
        && n' != "flake.nix"
        && !(v != "directory" && !(hasSuffix ".nix" n'))
        && !(v == "directory" && !(pathExists (d + "/${n'}/default.nix"))))
      (readDir d)
    );
  };
in {
  _doc = ''
    Platonic.Systems's extended nix library, preferably imported as `lib'`.
  '';

  /* More succinct version of tryEval
  */
  tryEval = {
    description = ''
      A more succinct version of tryEval, enabling use like `(tryEval e).value
      or e'`
    '';
    __functor = _: e: let
      e' = tryEval' e;
    in optionalAttrs e'.success { inherit (e') value; };
  };

  inherit importFromDir;
} // importFromDir ./. { inherit pkgs; }