client side

#include <SPI.h>
#include <MFRC522.h>
#include <WiFi.h>
#include <WiFiClient.h>
#include <ESP32Servo.h>
#include <ArduinoJson.h>

#define SS_PIN 5
#define RST_PIN 22
#define TOGGLE_PIN 33
#define PUSH_BUTTON_PIN 32
#define SERVO_PIN 15
#define GREEN_LED 2
#define RED_LED_GATE 4
#define RED_LED_MODE 21
#define BLOCK_ADDR 4

MFRC522 mfrc522(SS_PIN, RST_PIN);
Servo gateServo;
WiFiClient client;

const char* ssid = "oho";
const char* password = "123234345";
const char* server_ip = "192.168.186.221";
const uint16_t server_port = 5000;

String mode = "write";
bool gateOpen = false;
String rfidFromServer = "";

void setup() {
    Serial.begin(115200);
    SPI.begin();
    mfrc522.PCD_Init();

    pinMode(TOGGLE_PIN, INPUT_PULLUP);
    pinMode(PUSH_BUTTON_PIN, INPUT_PULLUP);
    pinMode(GREEN_LED, OUTPUT);
    pinMode(RED_LED_GATE, OUTPUT);
    pinMode(RED_LED_MODE, OUTPUT);

    digitalWrite(GREEN_LED, LOW);
    digitalWrite(RED_LED_GATE, LOW);
    digitalWrite(RED_LED_MODE, LOW);

    gateServo.attach(SERVO_PIN);
    gateServo.write(0);

    Serial.print("Connecting to Wi-Fi");
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
    Serial.println("\nWi-Fi connected.");
    
    if (client.connect(server_ip, server_port)) {
      Serial.println("Connected to the server");
    }
    sendModeToServer();
}

void loop() {
    static int lastState = HIGH;
    int currentState = digitalRead(TOGGLE_PIN);
    if (currentState == LOW && lastState == HIGH) {
        mode = (mode == "write") ? "read" : "write";
        Serial.println("Mode changed to: " + mode);
        sendModeToServer();
        delay(500);
    }
    lastState = currentState;

    if (digitalRead(PUSH_BUTTON_PIN) == LOW) {
        delay(200);
        toggleGate();
    }

    if (client.available()) {
      String response = "";
      while (client.available()) {
        char c = client.read();
        response += c;
      }
      parseServerResponse(response); 
    }

    if (mode == "write") {
        if (rfidFromServer.isEmpty()) return;
        digitalWrite(RED_LED_MODE, HIGH);
        if (mfrc522.PICC_IsNewCardPresent() && mfrc522.PICC_ReadCardSerial()) {
            writeToCard();
            digitalWrite(RED_LED_MODE, LOW);
        }
    } else if (mode == "read") {
        digitalWrite(RED_LED_MODE, LOW);
        if (mfrc522.PICC_IsNewCardPresent() && mfrc522.PICC_ReadCardSerial()) {
            sendRFIDToServer(readFromCard());
        }
    }
}

void toggleGate() {
    gateServo.write(gateOpen ? 0 : 90);
    gateOpen = !gateOpen;
    Serial.println(gateOpen ? "Gate opened." : "Gate closed.");
    delay(200);
}

void ensureConnection() {
  Serial.println("Reconnecting to server...");
  if (!client.connect(server_ip, server_port)) {
    Serial.println("Failed to reconnect to the server.");
  }
}

void sendModeToServer() {
  if (!client.connected()) ensureConnection(); 
  String message = "{\"mode\":\"" + mode + "\"}";
  Serial.println("Sending mode to server: " + message);
  client.println(message);
}

void parseServerResponse(String response) {
    Serial.println("Server response: " + response);
    StaticJsonDocument<512> doc;
    if (deserializeJson(doc, response)) {
        Serial.println("JSON deserialization failed.");
        return;
    }
    
    if (doc.containsKey("gate") && doc["gate"]) {
      Serial.println("Gate value is true, opening the gate...");
      if (!gateOpen) {
          digitalWrite(GREEN_LED, HIGH);
          digitalWrite(RED_LED_GATE, LOW);
          toggleGate();
          delay(5000);
          toggleGate();
          digitalWrite(GREEN_LED, LOW);
      }
    } else if(doc.containsKey("gate") && !doc["gate"]) {
        Serial.println("Gate value is false, keeping the gate closed.");
        digitalWrite(GREEN_LED, LOW);
        digitalWrite(RED_LED_GATE, HIGH);
        delay(5000);
        digitalWrite(RED_LED_GATE, LOW);
    }

    if (mode == "write" && doc["documents"].size() > 0) {
        rfidFromServer = doc["documents"][0]["rfid"].as<String>();
        Serial.println("RFID value from server: " + rfidFromServer);
    } else {
        rfidFromServer = "";
    }
}

void sendRFIDToServer(String rfid) {
    if (rfid.isEmpty()) return;
    if (!client.connected()) ensureConnection();
    String message = "{\"mode\":\"" + mode + "\",\"rfid\":\"" + rfid + "\"}";
    Serial.println("Sending RFID to server: " + message);
    client.println(message);
}

void writeToCard() {
    if (rfidFromServer.isEmpty()) return;

    MFRC522::MIFARE_Key key;
    memset(key.keyByte, 0xFF, 6);
    byte dataToWrite[16] = {0};

    for (int i = 0; i < rfidFromServer.length() && i < 16; i++) {
        dataToWrite[i] = rfidFromServer[i];
    }

    if (mfrc522.PCD_Authenticate(MFRC522::PICC_CMD_MF_AUTH_KEY_A, BLOCK_ADDR, &key, &(mfrc522.uid)) == MFRC522::STATUS_OK) {
        if (mfrc522.MIFARE_Write(BLOCK_ADDR, dataToWrite, 16) == MFRC522::STATUS_OK) {
            Serial.println("RFID write successful.");
            mode = "written";
            sendModeToServer();
            mode = "read";
            sendModeToServer();
        } else {
            Serial.println("Write failed.");
        }
        mfrc522.PICC_HaltA();
        mfrc522.PCD_StopCrypto1();
    } else {
        Serial.println("Authentication failed.");
    }
}

String readFromCard() {
    byte buffer[18], size = sizeof(buffer);
    MFRC522::MIFARE_Key key;
    memset(key.keyByte, 0xFF, 6);

    if (mfrc522.PCD_Authenticate(MFRC522::PICC_CMD_MF_AUTH_KEY_A, BLOCK_ADDR, &key, &(mfrc522.uid)) == MFRC522::STATUS_OK) {
        if (mfrc522.MIFARE_Read(BLOCK_ADDR, buffer, &size) == MFRC522::STATUS_OK) {
            mfrc522.PICC_HaltA();
            mfrc522.PCD_StopCrypto1();
            String rfidData = "";
            for (byte i = 0; i < 16 && buffer[i] != 0; i++) {
                rfidData += (char)buffer[i];
            }
            return rfidData;
        }
        Serial.println("Read failed.");
    } else {
        Serial.println("Authentication failed.");
    }
    return "";
}