nlock/flake.nix at main · OldUser101/nlock · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
{
  description = "Customisable, minimalist screen locker for Wayland";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

  outputs =
    {
      self,
      nixpkgs,
    }:
    let
      inherit (nixpkgs) lib;
      systems = [
        "aarch64-linux"
        "x86_64-linux"
      ];
      eachSystem = lib.genAttrs systems;

      shortRev = self.shortRev or self.dirtyShortRev or "unknown";
      overlays = import ./nix/overlays.nix { inherit shortRev; };

      pkgsFor = eachSystem (
        system:
        import nixpkgs {
          inherit system;
          overlays = [ overlays.nlock ];
        }
      );

      nixosModule = import ./nix/nixos-module.nix self;
      hmModule = import ./nix/hm-module.nix self;
    in
    {
      inherit overlays;

      packages = eachSystem (system: {
        default = self.packages.${system}.nlock;
        inherit (pkgsFor.${system}) nlock;
      });

      nixosModules = {
        default = self.nixosModules.nlock;
        nlock = nixosModule;
      };

      homeManagerModules = {
        default = self.homeManagerModules.nlock;
        nlock = hmModule;
      };

      devShells = eachSystem (system: {
        default =
          with pkgsFor.${system};
          mkShell {
            buildInputs = [
              cargo
              rustc
              rustfmt
              rust-analyzer
              pre-commit
              rustPackages.clippy

              cairo
              clang
              gdk-pixbuf
              glib
              libxkbcommon
              pam
              pango
              pkg-config
            ];

            RUST_SRC_PATH = rustPlatform.rustLibSrc;
            LIBCLANG_PATH = "${clang.cc.lib}/lib";
          };
      });
    };
}