ForgeDevPlugin/build.gradle at FD_7.0 · MinecraftForge/ForgeDevPlugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    id 'java-gradle-plugin'
    id 'groovy'
    id 'idea'
    id 'eclipse'
    id 'maven-publish'
    alias libs.plugins.gradleutils
    alias libs.plugins.gitversion
    alias libs.plugins.changelog
    alias libs.plugins.licenser
    alias libs.plugins.shadow apply false
}

gradleutils.displayName = 'ForgeDev'
description = "Forge's Gradle plugin to initialize and streamline the development of Minecraft Forge and its loader."
group = 'net.minecraftforge'
version = gitversion.tagOffset

println "Version: $version"

java {
    toolchain.languageVersion = JavaLanguageVersion.of(17)
    withSourcesJar()
}

gradleutils.pluginDevDefaults(configurations, libs.versions.gradle)

dependencies {
    implementation libs.srgutils
    implementation libs.fastcsv
    implementation libs.jarjar
    implementation libs.maven.artifact

    // Static Analysis
    compileOnly libs.nulls

    // Gradle API
    compileOnly libs.gradle

    // GradleUtils Shared Base
    implementation libs.gradleutils.shared

    // Plugins
    compileOnly libs.gradle.download

    // Utils
    implementation libs.bundles.asm
    implementation libs.bundles.utils
}

license {
    header = rootProject.file('LICENSE-header.txt')
    newLine = false
    exclude '**/*.properties'
}

tasks.named('jar', Jar) {
    archiveClassifier = 'thin'
}

pluginManager.withPlugin(libs.plugins.shadow.get().pluginId) {
    tasks.named('shadowJar', ShadowJar) {
        enableAutoRelocation = true
        archiveClassifier = null
        relocationPrefix = 'net.minecraftforge.forgedev.shadow'
    }
}

tasks.withType(Javadoc).configureEach {
    javadocTool = javaToolchains.javadocToolFor { languageVersion = JavaLanguageVersion.of(24) }
}

changelog {
    fromBase()
}

gradlePlugin {
    website = gitversion.url
    vcsUrl = gitversion.url + '.git'

    plugins {
        register('forgedev') {
            id = 'net.minecraftforge.forgedev'
            implementationClass = 'net.minecraftforge.forgedev.ForgeDevPlugin'
            displayName = gradleutils.displayName.get()
            description = project.description
            tags = ['minecraftforge']
        }

        register('convention') {
            id = 'net.minecraftforge.forge.build.convention'
            implementationClass = 'net.minecraftforge.forgedev.legacy.SharedBuildPlugin'
        }
    }
}

publishing {
    repositories {
        maven gradleutils.publishingForgeMaven
    }

    publications.register('pluginMaven', MavenPublication) {
        changelog.publish(it)
        gradleutils.promote(it)

        pom { pom ->
            name = gradleutils.displayName
            description = project.description

            gradleutils.pom.addRemoteDetails(pom)

            licenses {
                license gradleutils.pom.licenses.LGPLv2_1
            }

            developers {
                developer gradleutils.pom.developers.Jonathing
                developer gradleutils.pom.developers.LexManos
            }
        }
    }
}