Add String.join queries

Author: Marcono1234

codeql-custom-queries-java/queries/likely-bugs/String-join-not-joining.ql

@@ -0,0 +1,31 @@
+/**
+ * Finds calls to `String.join` with no or only one argument to join. In that case no joining
+ * is actually performed.
+ *
+ * For example:
+ * ```java
+ * // is equivalent to just `a` (respectively `String.valueOf(a)`)
+ * String.join("-", a)
+ * ```
+ *
+ * @id todo
+ * @kind problem
+ */
+
+import java
+
+from MethodAccess joinCall, Method joinMethod
+where
+  joinCall.getMethod() = joinMethod and
+  joinMethod.getDeclaringType() instanceof TypeString and
+  joinMethod.hasName("join") and
+  joinMethod.isStatic() and
+  // Only cover the varargs overload `String.join(CharSequence, CharSequence...)`
+  joinMethod.isVarargs() and
+  (
+    joinCall.getNumArgument() = 1
+    or
+    joinCall.getNumArgument() = 2 and
+    not joinCall.getArgument(1).getType() instanceof Array
+  )
+select joinCall, "Does not perform any joining"

codeql-custom-queries-java/queries/recommendations/String-join-instead-of-concat.ql

@@ -0,0 +1,27 @@
+/**
+ * Finds calls to `String.join` with only two arguments to join, instead of performing
+ * string concatenation.
+ *
+ * For example:
+ * ```java
+ * String.join("-", a, b)
+ * // can be simplified to
+ * a + "-" + b
+ * ```
+ *
+ * @id todo
+ * @kind problem
+ */
+
+import java
+
+from MethodAccess joinCall, Method joinMethod
+where
+  joinCall.getMethod() = joinMethod and
+  joinMethod.getDeclaringType() instanceof TypeString and
+  joinMethod.hasName("join") and
+  joinMethod.isStatic() and
+  joinMethod.isVarargs() and
+  // Separator + 2 varargs args
+  joinCall.getNumArgument() = 3
+select joinCall, "Can be replaced with string concatenation"