Add Vulkan submodules and CMake build support

Integrate Vulkan into the FFmpeg build by adding Vulkan-Headers and Vulkan-Loader as git submodules and new CMake support. Adds cmake/ffmpeg/vulkan.cmake which creates vulkan-headers and vulkan-loader targets (with installation into the build tree, pkg-config support, cross-compiling args and WSI options for Linux), wires the new target into cmake/ffmpeg/_main.cmake, and updates ffmpeg.cmake to pass include/lib paths and add a vulkan-loader dependency. Also updates .gitmodules and adds the gitlinks for the two submodules, and adjusts the CI workflow to stop installing distro Vulkan packages in favor of building the bundled components.

Author: ReenigneArcher

.github/workflows/ci.yml

@@ -212,7 +212,6 @@ jobs:
             "libdrm-dev:$package_arch"
             "libgl-dev:$package_arch"
             "libglx-dev:$package_arch"
-            "libvulkan-dev:$package_arch"
             "libwayland-dev:$package_arch"
             "libwayland-client0:$package_arch"
             "libx11-dev:$package_arch"
@@ -493,8 +492,6 @@ jobs:
               devel/pkgconf \
               graphics/libdrm \
               graphics/libglvnd \
-              graphics/vulkan-headers \
-              graphics/vulkan-loader \
               graphics/wayland \
               multimedia/libass \
               multimedia/libv4l \
@@ -506,6 +503,7 @@ jobs:
               x11/libxcb \
               x11/libXext \
               x11/libXfixes \
+              x11/libXrandr \
               x11/xorgproto
 
             # create symlink for shebang bash compatibility

.gitmodules

@@ -22,3 +22,11 @@
 	path = third-party/FFmpeg/SVT-AV1
 	url = https://github.com/LizardByte-infrastructure/SVT-AV1.git
 	branch = master
+[submodule "third-party/FFmpeg/Vulkan-Headers"]
+	path = third-party/FFmpeg/Vulkan-Headers
+	url = https://github.com/KhronosGroup/Vulkan-Headers.git
+	branch = main
+[submodule "third-party/FFmpeg/Vulkan-Loader"]
+	path = third-party/FFmpeg/Vulkan-Loader
+	url = https://github.com/KhronosGroup/Vulkan-Loader.git
+	branch = main

README.md

@@ -70,8 +70,6 @@ pkg install -y \
   devel/nasm \
   devel/ninja \
   devel/pkgconf \
-  graphics/vulkan-headers \
-  graphics/vulkan-loader \
   multimedia/libass \
   multimedia/libv4l \
   multimedia/libva \
@@ -102,7 +100,6 @@ sudo apt install -y \
     libsdl2-dev \
     libtool \
     libvorbis-dev \
-    libvulkan-dev \
     libxcb1-dev \
     libxcb-shm0-dev \
     libxcb-xfixes0-dev \

cmake/ffmpeg/_main.cmake

@@ -1,5 +1,6 @@
 # the destination directory needs to be same level down as the original source directory
-file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/third-party/FFmpeg DESTINATION ${CMAKE_CURRENT_BINARY_DIR})
+file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/third-party/FFmpeg DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
+        PATTERN "Vulkan-Loader/tests" EXCLUDE)  # vulkan loader test files contain emojis in file names which can fail
 
 set(FFMPEG_GENERATED_SRC_PATH ${CMAKE_CURRENT_BINARY_DIR}/FFmpeg/FFmpeg)
 set(AVCODEC_GENERATED_SRC_PATH ${CMAKE_CURRENT_BINARY_DIR}/FFmpeg/libavcodec)
@@ -52,6 +53,10 @@ if(BUILD_FFMPEG_LIBVA)
     include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/ffmpeg/libva.cmake)
 endif()
 
+if(BUILD_FFMPEG_VULKAN)
+    include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/ffmpeg/vulkan.cmake)
+endif()
+
 if(BUILD_FFMPEG_X264)
     include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/ffmpeg/x264.cmake)
 endif()

cmake/ffmpeg/ffmpeg.cmake

@@ -31,9 +31,11 @@ list(APPEND FFMPEG_EXTRA_CONFIGURE
         --extra-cflags='-I${CMAKE_CURRENT_BINARY_DIR_UNIX}/usr/local/include'
         --extra-cflags='-I${CMAKE_CURRENT_BINARY_DIR_UNIX}/x264/include'
         --extra-cflags='-I${CMAKE_CURRENT_BINARY_DIR_UNIX}/libva/include'
+        --extra-cflags='-I${CMAKE_CURRENT_BINARY_DIR_UNIX}/vulkan/include'
         --extra-ldflags='-L${CMAKE_CURRENT_BINARY_DIR_UNIX}/usr/local/lib'
         --extra-ldflags='-L${CMAKE_CURRENT_BINARY_DIR_UNIX}/x264/lib'
         --extra-ldflags='-L${CMAKE_CURRENT_BINARY_DIR_UNIX}/libva/lib'
+        --extra-ldflags='-L${CMAKE_CURRENT_BINARY_DIR_UNIX}/vulkan/lib'
         --extra-libs='-lpthread -lm'
         --disable-all
         --disable-autodetect
@@ -173,6 +175,9 @@ endif()
 if(BUILD_FFMPEG_LIBVA)
     add_dependencies(ffmpeg libva)
 endif()
+if(BUILD_FFMPEG_VULKAN)
+    add_dependencies(ffmpeg vulkan-loader)
+endif()
 if(BUILD_FFMPEG_X264)
     add_dependencies(ffmpeg x264)
 endif()

cmake/ffmpeg/vulkan.cmake

@@ -0,0 +1,81 @@
+# Vulkan Headers
+set(VULKAN_HEADERS_GENERATED_SRC_PATH ${CMAKE_CURRENT_BINARY_DIR}/FFmpeg/Vulkan-Headers)
+
+add_custom_target(vulkan-headers ALL
+        COMMAND ${CMAKE_COMMAND}
+            -S ${VULKAN_HEADERS_GENERATED_SRC_PATH}
+            -B ${CMAKE_CURRENT_BINARY_DIR}/vulkan-headers-build
+            -G "${CMAKE_GENERATOR}"
+            -DCMAKE_INSTALL_PREFIX=${CMAKE_CURRENT_BINARY_DIR}/vulkan
+            -DCMAKE_BUILD_TYPE=Release
+        COMMAND ${CMAKE_COMMAND}
+            --build ${CMAKE_CURRENT_BINARY_DIR}/vulkan-headers-build
+            --target install
+        WORKING_DIRECTORY ${VULKAN_HEADERS_GENERATED_SRC_PATH}
+        COMMENT "Target: Vulkan-Headers"
+        VERBATIM
+)
+add_dependencies(${CMAKE_PROJECT_NAME} vulkan-headers)
+
+# Vulkan Loader
+set(VULKAN_LOADER_GENERATED_SRC_PATH ${CMAKE_CURRENT_BINARY_DIR}/FFmpeg/Vulkan-Loader)
+
+# Configure options for Vulkan-Loader
+set(VULKAN_LOADER_CMAKE_ARGS
+        -DCMAKE_INSTALL_PREFIX=${CMAKE_CURRENT_BINARY_DIR}/vulkan
+        -DCMAKE_BUILD_TYPE=Release
+        -DCMAKE_C_FLAGS=${CMAKE_C_FLAGS}
+        -DCMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS}
+        -DVULKAN_HEADERS_INSTALL_DIR=${CMAKE_CURRENT_BINARY_DIR}/vulkan
+        -DBUILD_STATIC_LOADER=ON
+        -DBUILD_SHARED_LIBS=OFF
+        -DBUILD_TESTS=OFF
+        -DENABLE_WERROR=OFF
+)
+
+# Enable Wayland and X11 WSI for Linux and FreeBSD builds
+if(UNIX AND NOT APPLE)
+    list(APPEND VULKAN_LOADER_CMAKE_ARGS
+            -DBUILD_WSI_WAYLAND_SUPPORT=ON
+            -DBUILD_WSI_XCB_SUPPORT=ON
+            -DBUILD_WSI_XLIB_SUPPORT=ON
+    )
+endif()
+
+if(CMAKE_CROSSCOMPILING)
+    list(APPEND VULKAN_LOADER_CMAKE_ARGS
+            -DCMAKE_SYSTEM_NAME=${CMAKE_SYSTEM_NAME}
+            -DCMAKE_SYSTEM_PROCESSOR=${CMAKE_SYSTEM_PROCESSOR}
+            -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+            -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+    )
+    if(UNIX AND NOT APPLE)
+        list(APPEND VULKAN_LOADER_CMAKE_ARGS
+                -DCMAKE_C_COMPILER_TARGET=${CMAKE_C_COMPILER_TARGET}
+                -DCMAKE_CXX_COMPILER_TARGET=${CMAKE_CXX_COMPILER_TARGET}
+        )
+    endif()
+endif()
+
+add_custom_target(vulkan-loader ALL
+        COMMAND ${CMAKE_COMMAND}
+            -S ${VULKAN_LOADER_GENERATED_SRC_PATH}
+            -B ${CMAKE_CURRENT_BINARY_DIR}/vulkan-loader-build
+            -G "${CMAKE_GENERATOR}"
+            ${VULKAN_LOADER_CMAKE_ARGS}
+        COMMAND ${CMAKE_COMMAND}
+            --build ${CMAKE_CURRENT_BINARY_DIR}/vulkan-loader-build
+            --config Release
+            --target install
+            -- --jobs=${N_PROC}
+        WORKING_DIRECTORY ${VULKAN_LOADER_GENERATED_SRC_PATH}
+        COMMENT "Target: Vulkan-Loader"
+        VERBATIM
+        BYPRODUCTS
+            "${CMAKE_CURRENT_BINARY_DIR}/vulkan/lib/libvulkan.a"
+)
+add_dependencies(vulkan-loader vulkan-headers)
+add_dependencies(${CMAKE_PROJECT_NAME} vulkan-loader)
+
+# Add to PKG_CONFIG_PATH for FFmpeg to find
+set(PKG_CONFIG_PATH "${CMAKE_CURRENT_BINARY_DIR_UNIX}/vulkan/lib/pkgconfig:${PKG_CONFIG_PATH}")