SimpleLimbo/build.gradle at master · ItsAzni/SimpleLimbo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
plugins {
    id 'java'
    id 'eclipse'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group = 'com.itsazni'
version = '1.0.0'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
}

dependencies {
    compileOnly("com.velocitypowered:velocity-api:3.4.0-SNAPSHOT")
    compileOnly("net.kyori:adventure-nbt:4.17.0")

    // Netty (provided by Velocity at runtime)
    compileOnly("io.netty:netty-all:4.1.100.Final")

    // LimboAPI from direct file release
    compileOnly(files("libs/limboapi-1.1.27-SNAPSHOT.jar"))

    // Configurate for YAML config
    implementation("org.spongepowered:configurate-yaml:4.1.2")
}

def targetJavaVersion = 17
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.release.set(17)
}

def templateSource = file('src/main/templates')
def templateDest = layout.buildDirectory.dir('generated/sources/templates')
def generateTemplates = tasks.register('generateTemplates', Copy) { task ->
    def props = ['version': project.version]
    task.inputs.properties props

    task.from templateSource
    task.into templateDest
    task.expand props
}

sourceSets.main.java.srcDir(generateTemplates.map { it.outputs })

tasks.named('jar') {
    archiveClassifier.set('dev')
}

tasks.named('shadowJar') {
    archiveClassifier.set('')
    relocate 'org.spongepowered.configurate', 'com.itsazni.simpleLimbo.libs.configurate'
    relocate 'org.yaml.snakeyaml', 'com.itsazni.simpleLimbo.libs.snakeyaml'
}

tasks.named('build') {
    dependsOn tasks.named('shadowJar')
}