android-emulator-manager/build.gradle at master · Grigory-Rylov/android-emulator-manager · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
plugins {
    id "org.sonarqube" version "2.6"
    id 'java'
    id 'groovy'
    id 'jacoco'
    id "com.jfrog.bintray" version "1.7.3"
}

group 'com.github.grishberg'
version '0.3.16'

ext {
    PUBLISH_GROUP_ID = group
    PUBLISH_ARTIFACT_ID = 'android-emulator-manager'
    PUBLISH_VERSION = version
}

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    compile 'com.android.tools.build:gradle:2.3.0'
    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile "org.mockito:mockito-core:2.+"
    compile gradleApi()
    compile localGroovy()
    compile 'com.android.tools.ddms:ddmlib:25.3.0'
    // https://mvnrepository.com/artifact/org.apache.commons/commons-lang3
    compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.0'
    // https://mvnrepository.com/artifact/com.fasterxml.jackson.core/jackson-core
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: '2.9.2'
    compile group: 'com.google.code.findbugs', name: 'jsr305', version: '3.0.0'
}


sourceSets {
    test {
        java.srcDir 'src/test/unit/java'
    }
    integration {
        java.srcDir 'src/test/integration/java'
        resources.srcDir 'src/test/resources'
        compileClasspath += main.output + test.output
        runtimeClasspath += main.output + test.output
    }
}

configurations {
    integrationCompile.extendsFrom testCompile
    integrationRuntime.extendsFrom testRuntime
}

task integration(type: Test, description: 'Runs the integration tests.', group: 'Verification') {
    testClassesDir = sourceSets.integration.output.classesDir
    classpath = sourceSets.integration.runtimeClasspath
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = false
    }
}
tasks.sonarqube.dependsOn jacocoTestReport


test {
    jacoco {
        append = true
        includeNoLocationClasses = true
    }
}
apply from: 'sonar.gradle'

//need to call  ./gradlew clean build generateRelease
apply from: 'publish.gradle'

// ./gradlew bintrayUpload
apply from: 'deploy_in_jcenter.gradle'

apply plugin: 'maven-publish'
// ./gradlew publishToMavenLocal
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }
}