DirectFilePushClient/CMakeLists.txt at main · GoldenDragonJD/DirectFilePushClient · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
cmake_minimum_required(VERSION 3.19)
project(DirectFilePushClient LANGUAGES CXX)

find_package(Qt6 6.5 REQUIRED COMPONENTS Core Widgets Network)

qt_add_resources(RESOURCES_SRCS resource.qrc)

qt_standard_project_setup()

qt_add_executable(DirectFilePushClient
    WIN32 MACOSX_BUNDLE
    main.cpp
    mainwindow.cpp
    mainwindow.h
    mainwindow.ui
    message.h message.cpp message.ui
    filemessage.h filemessage.cpp filemessage.ui
    addipwindow.h addipwindow.cpp addipwindow.ui
    notificationmanager.h notificationmanager.cpp
    encryptionwindow.h encryptionwindow.cpp encryptionwindow.ui
    SimpleStreamCipher.h
    hmac.h
    ${RESOURCES_SRCS}
    settingswindow.h settingswindow.cpp settingswindow.ui
)

target_link_libraries(DirectFilePushClient
    PRIVATE
        Qt6::Core
        Qt6::Widgets
        Qt6::Network
)

include(GNUInstallDirs)

# Standard install for Linux/Flatpak
install(TARGETS DirectFilePushClient
    BUNDLE  DESTINATION .
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
)

# ONLY run deployment for Windows/macOS/Local bundles.
# FLATPAK_ID is automatically set by flatpak-builder.
if(NOT DEFINED ENV{FLATPAK_ID})
    qt_generate_deploy_app_script(
        TARGET DirectFilePushClient
        OUTPUT_SCRIPT deploy_script
        NO_UNSUPPORTED_PLATFORM_ERROR
    )
    install(SCRIPT ${deploy_script})
endif()