CosmicReach-Example-Mod/build.gradle at master · ForwarD-NerN/CosmicReach-Example-Mod · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
plugins {
    id 'java'
    id 'maven-publish'
    id "de.undercouch.download" version "5.6.0"
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

version = project.mod_version
group = project.maven_group

base {
    archivesName = "$mod_name-CR-$cosmicreach_version"
}

repositories {
    mavenCentral()
    maven {
        url 'https://jitpack.io'
    }
    maven {
        url "https://repo.spongepowered.org/maven/"
    }
    maven {
        url "https://maven.fabricmc.net/"
    }
}

sourceSets {
    main {
        java {
            srcDir 'src'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'run/', include: ['*.jar'])
    implementation fileTree(dir: 'run/deps', include: ['*.jar'])
}

processResources {
    inputs.property "version", project.version
    inputs.property "loader_version", project.loader_version
    inputs.property "cosmicreach_version", project.cosmicreach_version
    inputs.property "mod_name", project.mod_name
    inputs.property "modid", project.modid
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version,
                "loader_version": project.loader_version,
                "cosmicreach_version": project.cosmicreach_version,
                "mod_name": project.mod_name,
                "modid": project.modid
    }
}

tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    it.options.release = 17
}

tasks.register('buildAndCopy', Copy) {
    group 'build'
    dependsOn 'assemble'
    from "build/libs/"
    into "run/mods"
}


tasks.register('downloadModLoader', Download) {
    group 'fabric'
    src "https://github.com/ForwarD-NerN/CosmicReach-Mod-Loader/releases/download/latest/cosmicreach-fabric-modloader.zip"
    dest "run/"
}

tasks.register('downloadJars', Download) {
    dependsOn downloadModLoader
    group 'fabric'
    src "https://github.com/CRModders/CosmicArchive/raw/main/Cosmic%20Reach-${cosmicreach_version}.jar"
    dest "run/"
}

tasks.register('createRunFolder') {
    group 'fabric'
    doFirst {
        mkdir("run/")
    }
}

tasks.register('setupEnvironment', Copy) {
    group 'fabric'
    dependsOn createRunFolder
    dependsOn downloadJars

    from zipTree(file(new File("run/cosmicreach-fabric-modloader.zip")))
    into "run/"
    exclude("launch.sh", "launch.bat")

    doLast {
        var gameJar = fileTree("${project.rootDir}/run/").filter { file ->
            return file.name.startsWith("Cosmic Reach-") || file.name.startsWith("Cosmic%20Reach-")
        }
        if(!gameJar.getFiles().isEmpty()) {
            gameJar.getSingleFile().renameTo("run/cosmic-reach.jar")
        }
        delete("run/cosmicreach-fabric-modloader.zip")
    }
}