Menu Scripts 1.12.cmd

@echo off
title Menu Scripts
chcp 65001
cls

:: BatchGotAdmin
REM verifica o status de execução do script como administrador, solicita a permissão e inicia o script novamente
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
	echo Requisitando privilégios de administrador...
	goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
	echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
	copy %0 "%temp%\fgms.cmd" /y
	echo UAC.ShellExecute "cmd.exe", "/K %temp%\fgms.cmd", "", "runas", 1 >> "%temp%\getadmin.vbs"
	"%temp%\getadmin.vbs"
	del "%temp%\getadmin.vbs"
	exit /B
:gotAdmin
	pushd "%CD%"
	CD /D "%~dp0"

:inicio
REM Mensagem de aviso.
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #       Atualize o aplicativo "instalador de aplicativo" na Microsoft Store caso o script não funcione.       #
echo #                                                                                                             #
echo ===============================================================================================================
pause
goto menu

:menu
REM Menu principal do script com seleção de opção por número.
cls
echo ===============================================================================================================
echo #                                              Menu Scripts 1.12                                              #
echo ===============================================================================================================
echo #                                                                                                             #
echo #                                            Selecione uma opção:                                             #
echo #                                                                                                             #
echo #                                         1 - Configuração inicial completa                                   #
echo #                                         2 - Limpar programas pré-instalados                                 #
echo #                                         3 - Instalar programas básicos                                      #
echo #                                         4 - Instalar Offices                                                #
echo #                                         5 - Otimizar                                                        #
echo #                                         6 - Aplicativos                                                     #
echo #                                         7 - Resolução de Problemas                                          #
echo #                                         8 - Drivers                                                         #
echo #                                         9 - Sobre                                                           #
echo #                                         0 - Sair                                                            #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opção:
if "%opcao%"=="1" goto inicial
if "%opcao%"=="2" goto limpar
if "%opcao%"=="3" goto programas
if "%opcao%"=="4" goto office
if "%opcao%"=="5" goto otimizar
if "%opcao%"=="6" goto apps
if "%opcao%"=="7" goto problemas
if "%opcao%"=="8" goto drivers
if "%opcao%"=="9" goto sobre
if "%opcao%"=="0" exit
goto menu

:inicial
REM Essa opção serve para pcs recém formatados, configura energia em alto desempenho, roda comandos condensados para desinstalar bloatwares e um trecho para instalar programas básicos e verifica a update dos aplicativos instalados.
cls
echo Selecionando modo de energia Alto Desempenho
powercfg -setactive 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
echo Desinstalando bloatwares
:desinstalar
REM Esse próximo código desinstala apenas bloatwares embarcados no Windows 11 25H2 todas as edições
winget uninstall 9NBLGGH4QGHW 9WZDNCRFJ3Q2 9NBLGGH4R32N 9WZDNCRFHVFW 9P1J8S7CCWWT 9NZBF4GT040C 9NBLGGH5R558 Microsoft.Teams Microsoft.MicrosoftSolitaireCollection_8wekyb3d8bbwe Microsoft.YourPhone_8wekyb3d8bbwe Microsoft.GetHelp_8wekyb3d8bbwe --accept-source-agreements
if "%1"=="X" exit /B
winget uninstall Microsoft.OutlookForWindows_8wekyb3d8bbwe
winget uninstall Microsoft.OneDrive
winget uninstall 9PDJDJS743XF
winget uninstall 9WZDNCRD29V9
echo Instalando apps
call :instalar Y
echo Atualizando apps
winget upgrade --all --include-unknown
pause
goto menu

:limpar
cls
REM Os trechos seguintes desinstalam bloatwares individualmente desde a versão 1903 do Windows 10 até as mais recentes do windows 10 e 11, para que não hajam interrupções por erro no winget.
echo Desinstalando aplicativos bloatwares preinstalados com o Windows
call :desinstalar X
winget uninstall 9NBLGGH4QGHW 9WZDNCRFJ3Q2 9WZDNCRFJ3P2 9WZDNCRDTBJJ 9NBLGGH4R32N 9NBLGGH42THS 9NG1H8B3ZC7M 9WZDNCRDTBVB 9NFFX4SZZ23L 9WZDNCRD29V9 9WZDNCRFJ364 9WZDNCRFHVQM Microsoft.Office.OneNote_8wekyb3d8bbwe Microsoft.MicrosoftSolitaireCollection_8wekyb3d8bbwe Microsoft.YourPhone_8wekyb3d8bbwe Microsoft.XboxApp_8wekyb3d8bbwe Microsoft.GetHelp_8wekyb3d8bbwe Microsoft.OneDrive --accept-source-agreements
winget uninstall 9NBLGGH4QGHW
winget uninstall 9WZDNCRFJ3Q2
winget uninstall 9WZDNCRFJ3P2
winget uninstall 9WZDNCRDTBJJ
winget uninstall 9NBLGGH4R32N
winget uninstall 9WZDNCRD29V9
winget uninstall 9WZDNCRFHVFW
winget uninstall 9NBLGGH42THS
winget uninstall 9NG1H8B3ZC7M
winget uninstall 9P1J8S7CCWWT
winget uninstall 9PDJDJS743XF
winget uninstall 9WZDNCRDTBVB
winget uninstall 9NBLGGH5R558
winget uninstall 9NFFX4SZZ23L
winget uninstall 9NZBF4GT040C
winget uninstall 9NRX63209R7B
winget uninstall 9WZDNCRFHWD2
winget uninstall XPFFZHVGQWWLHB
winget uninstall 9WZDNCRD29V9
winget uninstall 9WZDNCRFHVQM
winget uninstall 9NCBCSZSJRSB
winget uninstall 9WZDNCRF0083
winget uninstall 9NH2GPH4JZS4
winget uninstall 9NKSQGP7F2NH
winget uninstall 9NWD3S85MTFB
winget uninstall 9NBLGGH5L9XT
winget uninstall 9WZDNCRFJ364
winget uninstall Disney.37853FC22B2CE_6rarf9sa4v8jt
winget uninstall AmazonVideo.PrimeVideo_pwbj9vvecjh7j
winget uninstall Microsoft.OneDrive
winget uninstall Microsoft.Teams
winget uninstall Microsoft.OutlookForWindows_8wekyb3d8bbwe
winget uninstall Microsoft.YourPhone_8wekyb3d8bbwe
winget uninstall Microsoft.GetHelp_8wekyb3d8bbwe
winget uninstall Microsoft.MicrosoftSolitaireCollection_8wekyb3d8bbwe
pause
goto menu

:programas
cls
REM Próximo trecho instala o winrar, o java, chrome, firefox, acrobat reader e plugins de execução de vídeo e imagem
echo Instalando apps
:instalar
winget install RARLab.WinRAR Oracle.JavaRuntimeEnvironment Google.Chrome 9NZVDKPMR9RD Adobe.Acrobat.Reader.64-bit 9NCTDW2W1BH8 9MVZQVXJBQ9V 9N95Q1ZZPMH4 9N4D0MSMP0PT 9N0DX20HK701 --accept-package-agreements
if "%1"=="Y" exit /B
pause
goto menu

:office
REM essa seção dá opções de aplicativos para escritório gratuitos ou por assinatura, ao selecionar ele faz download e instala os respectivos aplicativos.
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #                                          Selecione o App desejado:                                          #
echo #                                                                                                             #
echo #                                          1 - Microsoft Office                                               #
echo #                                          2 - Libre Office                                                   #
echo #                                          3 - Only Office                                                    #
echo #                                          4 - WPS Office                                                     #
echo #                                          0 - Voltar                                                         #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opcao:
if "%opcao%"=="1" goto microsoft
if "%opcao%"=="2" goto libre
if "%opcao%"=="3" goto only
if "%opcao%"=="4" goto wps
if "%opcao%"=="0" goto menu
goto menu

:microsoft
cls
winget install 9WZDNCRD29V9
pause
goto menu

:libre
cls
winget install TheDocumentFoundation.LibreOffice
pause
goto menu

:only
cls
winget install ONLYOFFICE.DesktopEditors
pause
goto menu

:wps
cls
winget install 9NSGM705MQWC
pause
goto menu

:otimizar
REM Essa opção seleciona o modo de energia alto desempenho, verifica a atualização de aplicativos compatíveis com winget, executa todas as instancias do dism, executa a verificação de arquivos do sistema, desfragmenta e invoca o checkdisk
cls
echo Selecionando modo de energia Alto Desempenho
powercfg -setactive 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
echo Atualizando apps instalados
winget upgrade --all --include-unknown
Echo Rodando DISM
dism.exe /online /cleanup-image /restorehealth
dism.exe /online /cleanup-image /startcomponentcleanup
echo Rodando SFC Scannow
sfc /scannow
echo Rodando Defrag
chcp 1252 > nul
for /f "skip=1" %%d in ('wmic logicaldisk get caption') do (
    defrag %%d /h /u /v
)
chcp 65001 > nul
echo Rodando Checkdisk
chkdsk /F /R
pause
goto menu

:apps
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #                                         Selecione a opção desejada:                                         #
echo #                                                                                                             #
echo #                                          1 - Pesquisar Apps                                                 #
echo #                                          2 - Atualizar Apps instalados                                      #
echo #                                          3 - DirectX                                                        #
echo #                                          4 - MSI Afterburner                                                #
echo #                                          5 - VC Redist                                                      #
echo #                                          6 - MAS                                                            #
echo #                                          7 - FastFetch                                                      #
echo #                                          0 - Voltar                                                         #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opcao:
if "%opcao%"=="1" goto pesquisar
if "%opcao%"=="2" goto atualizar
if "%opcao%"=="3" goto dx
if "%opcao%"=="4" goto afterburner
if "%opcao%"=="5" goto vcred
if "%opcao%"=="6" goto mas
if "%opcao%"=="7" goto fastfetch
if "%opcao%"=="0" goto menu
goto menu

:pesquisar
REM Dá uma interface para pesquisa e instalação de aplicativos através do winget
cls
set /p app=Digite o nome do aplicativo:
winget search "%app%"

echo O que deseja fazer?:
echo 1 - Instalar
echo 2 - Continuar pesquisando
echo 0 - Voltar
set /p opcao="Opcao:"
if "%opcao%"=="1" goto instalarapp
if "%opcao%"=="2" goto pesquisar
if "%opcao%"=="0" goto apps

:instalarapp
set /p app="Digite o ID do aplicativo:"
winget install "%app%"
pause
goto apps

:atualizar
REM Atualiza os aplicativos do pc compatíveis com winget.
cls
winget upgrade --all --include-unknown
pause
goto apps

:dx
REM Instala o DirectX End-User Runtime Web.
cls
winget install Microsoft.DirectX
pause
goto apps

:afterburner
REM Instala o MSI Afterburner e o complemento RivaTuner Statistics Server, além do plugin DirectX necessário para rodar.
cls
winget install Microsoft.DirectX Guru3D.Afterburner Guru3D.RTSS
pause
goto apps

:vcred
REM Instala o VCRedist All In One.
cls
winget install abbodi1406.vcredist
pause
goto apps

:mas
cls
start "ps" powershell.exe -command "irm https://get.activated.win | iex"
echo Siga as instruções para utilizar o MAS.
pause
goto apps

:fastfetch
cls
winget install Fastfetch-cli.Fastfetch
pause
goto apps

:problemas
REM Essa seção dá opções de solução para problemas comuns e conhecidos do windows.
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #                                                  Selecione:                                                 #
echo #                                                                                                             #
echo #                                    1  - Limpar temps e prefetch (Reiniciar)                                 #
echo #                                    2  - Reinstalar Defender                                                 #
echo #                                    3  - Resetar Rede e Firewall para config de Fábrica (Reiniciar)          #
echo #                                    4  - Resetar IP                                                          #
echo #                                    5  - Entrar na BIOS (Reiniciar)                                          #
echo #                                    6  - Dism                                                                #
echo #                                    7  - SFC Scannow                                                         #
echo #                                    8  - CheckDisk                                                           #
echo #                                    9  - Limpeza de disco                                                    #
echo #                                    10 - Desfragmentar                                                       #
echo #                                    11 - Criar ponto de restauração                                          #
echo #                                    12 - Verificar assinatura de drivers                                     #
echo #                                    13 - Ferramenta de Remoção de Software Mal-Intencionado                  #
echo #                                    14 - Visualizador de Eventos                                             #
echo #                                    0  - Voltar                                                              #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opcao:
if "%opcao%"=="1" goto temp
if "%opcao%"=="2" goto defender
if "%opcao%"=="3" goto resetrede
if "%opcao%"=="4" goto resetip
if "%opcao%"=="5" goto bios
if "%opcao%"=="6" goto dism
if "%opcao%"=="7" goto sfc
if "%opcao%"=="8" goto chk
if "%opcao%"=="9" goto limpadisco
if "%opcao%"=="10" goto defrag
if "%opcao%"=="11" goto restaura
if "%opcao%"=="12" goto signature
if "%opcao%"=="13" goto msrt
if "%opcao%"=="14" goto eventos
if "%opcao%"=="0" goto menu
pause
goto menu

:temp
cls
echo Ao finalizar o procedimento, digite exit e reinicie o pc.
pause
rmdir /q /s "%systemroot%\Prefetch\"
rmdir /q /s "%systemroot%\temp\"
rmdir /q /s "%temp%\"
pause
goto problemas

:defender
cls
start "ps" powershell.exe -Command "Get-AppxPackage Microsoft.SecHealthUI -AllUsers | Reset-AppxPackage"
echo Reinicie o computador após a conclusão do comando e reabra o defender para conferir se foi resetado.
pause
goto problemas

:resetrede
cls
netsh winsock reset
netsh int ip reset
netsh advfirewall reset
ipconfig /release
ipconfig /renew
ipconfig /flushdns
echo Teste a rede para verificar se o problema foi solucionado.
pause
goto problemas

:resetip
cls
netsh winsock reset
ipconfig /release
ipconfig /renew
ipconfig /flushdns
echo Teste a rede para verificar se o problema foi solucionado.
pause
goto problemas

:bios
cls
echo Pressione qualquer tecla para reiniciar o computador e entrar na bios, caso falhe execute novamente o comando.
pause
shutdown /r /fw /t 000
pause
goto problemas

:dism
cls
dism.exe /online /cleanup-image /restorehealth
dism.exe /online /cleanup-image /startcomponentcleanup
pause
goto problemas

:sfc
cls
sfc /scannow
pause
goto problemas

:chk
cls
chkdsk /F /R
pause
goto problemas

:limpadisco
cls
echo Siga as instruções para selecionar os componentes para limpar.
cleanmgr
pause
goto problemas

:defrag
cls
echo Siga as instruções para desfragmentar ou realizar TRIM.
dfrgui
pause
goto problemas

:restaura
cls
echo Siga as instruções para criar um ponto de restauração do sistema.
SystemPropertiesProtection.exe
pause
goto problemas

:signature
cls
echo Siga as instruções para verificar a assinatura dos drivers do Windows.
sigverif
pause
goto problemas

:msrt
cls
echo Siga as instruições para usar a ferramenta de remoção de software mal-intencionado.
mrt
pause
goto problemas

:eventos
cls
echo Siga as instruções para visualizar os eventos do Windows.
eventvwr
pause
goto problemas

:drivers
REM Essa seção dá opções de drivers para serem baixados e instalados no seu pc, alguns são automatizados, outros somente execução manual.
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #                                      Selecione a marca do dispositivo:                                      #
echo #                                                                                                             #
echo #                                               1  - Intel                                                    #
echo #                                               2  - AMD                                                      #
echo #                                               3  - Nvidia                                                   #
echo #                                               4  - Lenovo                                                   #
echo #                                               5  - Samsung                                                  #
echo #                                               6  - MSI                                                      #
echo #                                               7  - Dell                                                     #
echo #                                               8  - Acer (Beta)                                              #
echo #                                               9  - HP                                                       #
echo #                                               10 - Asus                                                     #
echo #                                               11 - Asrock                                                   #
echo #                                               0  - Voltar                                                   #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opcao:
if "%opcao%"=="1" goto intel
if "%opcao%"=="2" goto amd
if "%opcao%"=="3" goto nvidia
if "%opcao%"=="4" goto lenovo
if "%opcao%"=="5" goto samsung
if "%opcao%"=="6" goto msi
if "%opcao%"=="7" goto dell
if "%opcao%"=="8" goto acer
if "%opcao%"=="9" goto hp
if "%opcao%"=="10" goto asus
if "%opcao%"=="11" goto asrock
if "%opcao%"=="0" goto menu
goto menu

:intel
cls
winget install Intel.IntelDriverAndSupportAssistant
echo Após a instalação haverá um ícone na barra de ícones ao lado da barra de rede, som, etc, com o nome 
echo "Intel Driver & Support Assistant", clique com o botão direito e clique em verificar atualizações,
echo o mesmo abrirá o navegador e analizará os drivers, basta clicar em instalar tudo.
pause
goto menu

:amd
cls
start "web" "https://www.amd.com/pt/support/download/drivers.html"
echo Ache na lista descrita o modelo do Processador (Se for APU) e/ou modelo do Chipset e/ou Placa de vídeo,
echo clique em "Enviar" e ele irá para a pagina de destino, baixe o driver correspondente a versão do SO e instale.
pause
goto menu

:nvidia
cls
start "web" "https://www.nvidia.com/pt-br/software/nvidia-app/"
echo Clique em "Baixar agora", após o download Execute o Nvidia APP, siga as instruções para verificar,
echo baixar e instalar os drivers da placa de vídeo.
pause
goto menu

:lenovo
cls
winget install Lenovo.SystemUpdate
echo Execute o aplicativo "System Update" e avance para a instalação de drivers do dispositivo.
pause
goto menu

:samsung
cls
winget install 9NBLGGH4XDV0
echo Execute o aplicativo "Samsung Device Care" e siga as instruções para instalar os drivers do dispositivo..
pause
goto menu

:msi
cls
winget install 9NVMNJCR03XV
echo Execute o aplicativo "MSI Center", Selecione a opção Support e vá em Live Update, clique em verificar e
echo instale os drivers necessários.
pause
goto menu

:dell
cls
start "web" "https://dl.dell.com/serviceability/eSupport/SupportAssistLauncher.exe"
echo Execute o aplicativo "SupportAssistLauncher.exe" que foi baixado na pasta downloads, ao finalizar a instalação 
echo clique na seta inferior na janela aberta e utilize a seção drivers para buscar e instalar os mesmos.
pause
goto menu

:acer
cls
Winget install ULICTekInc.AcerSense5.0_nt9dgb7efx6bt
echo Execute o aplicativo "AcerSense", siga as instruções, ao chegar na pagina principal utilize a seção drivers
echo para buscar e instalar os mesmos.
pause
goto menu

:hp
cls
start "web" "https://support.hp.com/br-pt/help/hp-support-assistant"
echo Siga as instruções do site para selecionar seu dispositivo, selecione "Deixe a HP detectar seu produto" e 
echo inicie o download, execute o app, instale, vá em meu dispositivo e na aba downloads utilize a seção drivers
echo para buscar e instalar os mesmos.
pause
goto menu

:asus
cls
start "web" "https://driverhub.asus.com/en"
echo Siga as instruções para baixar e instalar o Asus DriverHUB.
pause
goto menu

:asrock
cls
start "web" "https://www.asrock.com/support/index.br.asp"
echo Siga as instruções do site para localizar o modelo, selecione suporte, drivers e firmware, selecione a versão
echo do sistema operacional, baixe os drivers desejados e execute manualmente um por um usando "Setup" dentro das
echo pastas baixadas no site.
pause
goto menu

:sobre
REM Essa seção serve apenas para créditos, texto explicativo e direcionamento para sites oficiais.
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #                                                  Selecione:                                                 #
echo #                                                                                                             #
echo #                                               1 - Manual                                                    #
echo #                                               2 - Créditos e suporte                                        #
echo #                                               0 - Voltar                                                    #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opcao:
if "%opcao%"=="1" goto manual
if "%opcao%"=="2" goto creditos
if "%opcao%"=="0" goto menu
goto menu

:manual
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #    Este Script é utilizado para automatizar e facilitar a configuração, manutenção do Windows, instalação   #
echo # de aplicativos utilizando o gerenciador de pacotes winget e mais outros comandos CMD (prompt de comandos).  #
echo # Você pode utilizar ele usando os números do teclado e a tecla enter para navegar entre as opções e utilizá- #
echo # las, e Ctrl + C para interromper os comandos em execução.                                                   #
echo #                                                                                                             #
echo #   Opção 1 configuração inicial completa: Configura o Windows desinstalando aplicativos pré-instalados       #
echo # do sistema (bloatwares) instalando aplicativos básicos (Winrar, Java, Chrome, Firefox, Acrobat Reader,      #
echo # codecs de vídeo e coloca no modo alto desempenho.                                                           #
echo #   Opção 2 Limpar programas pré-instalados: Faz a mesma limpeza de bloatwares da Opção 1.                    #
echo #   Opção 3 Instalar programas básicos: Instala os mesmos apps da Opção 1.                                    #
echo #   Opção 4 Instalar Offices: Mostra opções de aplicativos para escritório para instalação.                   #
echo #   Opção 5 Otimizar: Coloca no alto desempenho, atualiza todos os apps compatíveis com winget, executa       #
echo # sfc /scannow, dism, desfragmenta todos os discos conectados e executa o chkdsk (Opcional).                  #
echo #   Opção 6 Aplicativos: Dá opções para pesquisar apps compatíveis com winget ou atualizar eles.              #
echo #   Opção 7 Resolução de problemas: Dá opções que podem solucionar problemas do windows.                      #
echo #   Opção 8 Drivers: Dá opções de fabricantes para buscar drivers de dispositivos.                            #
echo #                                                                                                             #
echo ===============================================================================================================
pause
goto sobre

:creditos
cls
echo ===============================================================================================================
echo #                                                                                                             #
echo #    Este script foi desenvolvido Por Fal_Gamerr, obrigado a RyanK_, Samuca, Ofernandofilo e Maugusto por     #
echo # auxiliar na criação do script.                                                                              #
echo #    Nos aplicativos a opção 6 MAS é um projeto de terceiros com Licença GNU GPL V3.0 com o seguinte Site:    #
echo # "https://github.com/massgravel/Microsoft-Activation-Scripts"                                                #
echo #    Compatível com Windows 10 e 11 com a última versão do instalador de aplicativos da Microsoft Store.      #
echo #    Caso queira contribuir com o projeto com uma doação, doe para a chave pix: falgamerr@gmail.com           #
echo #                                                                                                             #
echo #                                               1 - Site oficial                                              #
echo #                                               2 - Checar atualizações                                       #
echo #                                               3 - Canal no Youtube                                          #
echo #                                               4 - Instagram                                                 #
echo #                                               0 - Voltar                                                    #
echo #                                                                                                             #
echo ===============================================================================================================
set /p opcao=Opcao:
if "%opcao%"=="1" start "web" "https://github.com/FalGamerr/Menu-Scripts"
if "%opcao%"=="2" start "web" "https://github.com/FalGamerr/Menu-Scripts/releases/"
if "%opcao%"=="3" start "web" "https://youtube.com/user/FalGamerr"
if "%opcao%"=="4" start "web" "https://instagram.com/fabricio.yan.mm/"
if "%opcao%"=="0" goto sobre
goto sobre