AMXModX/plugin_autoloader.sma at master · DouglasSherk/AMXModX · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
#include <amxmodx>
#include <amxmisc>

#define MAX_PLUGINS 200

new g_Plugin

enum _:PLUGINS
{
	LOADED,
	UNLOADED,
	PAUSED,
	DEBUG
}

new g_Plugins[PLUGINS][MAX_PLUGINS][33]
new g_PluginsNum[PLUGINS]

new g_ConfigFile[128]

public plugin_init()
{
	g_Plugin = register_plugin("Plugin Autoloader","1.0","Hawk552")
	LoadPlugins()
}

LoadPlugins()
{
	get_configsdir(g_ConfigFile,127)
	add(g_ConfigFile,127,"/autoloader.ini")

	new File = fopen(g_ConfigFile,"rt")
	if(!File)
		return

	new Buffer[128],Left[64],Right[64]
	while(!feof(File))
	{
		fgets(File,Buffer,127)

		if(Buffer[0] == ';')
			continue

		parse(Buffer,Left,63,Right,63)
		replace_all(Buffer,127,"^n","")
		remove_quotes(Left)
		trim(Left)
		remove_quotes(Right)
		trim(Right)

		if(containi(Left,".amx") == -1)
			continue

		if(equali(Right,"pause"))
			copy(g_Plugins[PAUSED][g_PluginsNum[PAUSED]++],32,Left)
		else if(equali(Right,"unload"))
			copy(g_Plugins[UNLOADED][g_PluginsNum[UNLOADED]++],32,Left)
		else if(equali(Right,"debug"))
			copy(g_Plugins[DEBUG][g_PluginsNum[DEBUG]++],32,Left)

	}

	fclose(File)

	get_localinfo("amxx_plugins",g_ConfigFile,127)
	File = fopen(g_ConfigFile,"rt")
	if(!File)
		return

	new SplitHolder[2]
	while(!feof(File))
	{
		fgets(File,Buffer,127)
		if(containi(Buffer,";") != -1)
			strtok(Buffer,Buffer,127,SplitHolder,1,';',1)

		if(containi(Buffer,".amx") != -1)
		{
			replace(Buffer,127," debug","")
			remove_quotes(Buffer)
			trim(Buffer)
			copy(g_Plugins[UNLOADED][g_PluginsNum[UNLOADED]++],32,Buffer)
		}
	}

	fclose(File)

	new Num = get_pluginsnum(),Dummy[2]
	for(new Count = 1;Count <= Num;Count++)
	{
		get_plugin(Count,g_Plugins[LOADED][g_PluginsNum[LOADED]],32,Dummy,1,Dummy,1,Dummy,1,Dummy,1)

		for(new Count2;Count2 < g_PluginsNum[PAUSED];Count2++)
			if(equali(g_Plugins[PAUSED][Count2],g_Plugins[LOADED][g_PluginsNum[LOADED]]))
				server_cmd("amxx pause ^"%s^"",g_Plugins[LOADED][g_PluginsNum[LOADED]++])
	}

	new FileName[128]
	get_configsdir(FileName,127)
	add(FileName,127,"/plugins-autoloader.ini")
	delete_file(FileName)

	File = fopen(FileName,"wt")
	if(!File)
		return

	new Directory[64],Plugin[64],Pos,Garbage,ThisPlugin[64],Flag
	// the only important thing here is the name itself
	get_plugin(g_Plugin,ThisPlugin,63,Plugin,1,Plugin,1,Plugin,1,Plugin,1)
	get_localinfo("amxx_pluginsdir",Directory,63)

	while(read_dir(Directory,Pos++,Plugin,63,Garbage))
	{
		if(!Plugin[0] || equali(Plugin,".") || equali(Plugin,"..") || equali(ThisPlugin,Plugin) || containi(Plugin,"rem-") != -1)
			continue

		Flag = 0
		for(new Count;Count < g_PluginsNum[UNLOADED];Count++)
		{
			if(equali(g_Plugins[UNLOADED][Count],Plugin))
			{
				Flag = 1
				break
			}
		}

		if(Flag)
			continue

		fputs(File,Plugin)
		for(new Count;Count < g_PluginsNum[DEBUG];Count++)
			if(equali(Plugin,g_Plugins[DEBUG][Count]))
			{
				fputs(File," debug")
				break
			}
		fputs(File,"^n")
	}

	fclose(File)

}

public plugin_end()
	LoadPlugins()