func/CMakeLists.txt at master · Dimankarp/func · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
cmake_minimum_required(VERSION 3.27)


project(Compiler CXX C)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

# Find dependencies

find_package(FLEX REQUIRED)
find_package(BISON REQUIRED)

find_package(LLVM REQUIRED CONFIG)
message(STATUS "Found LLVM ${LLVM_PACKAGE_VERSION}")
message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")

# Flex & Bison

set(LEXER_SOURCE "${CMAKE_CURRENT_SOURCE_DIR}/src/codegen/lexer.l")
set(PARSER_SOURCE "${CMAKE_CURRENT_SOURCE_DIR}/src/codegen/parser.y")


set(LEXER_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/codegen")
set(PARSER_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/codegen")


flex_target(LEXER ${LEXER_SOURCE} ${LEXER_OUTPUT_DIR}/lexer.cpp
           DEFINES_FILE ${LEXER_OUTPUT_DIR}/lexer.hpp)
bison_target(PARSER ${PARSER_SOURCE} ${PARSER_OUTPUT_DIR}/parser.tab.cpp
            DEFINES_FILE ${PARSER_OUTPUT_DIR}/parser.tab.hpp
            COMPILE_FLAGS "-v --language=c++ -Wconflicts-sr -Wcounterexamples")

add_flex_bison_dependency(LEXER PARSER)


# LLVM Defines

separate_arguments(LLVM_DEFINITIONS_LIST NATIVE_COMMAND ${LLVM_DEFINITIONS})
add_definitions(${LLVM_DEFINITIONS_LIST})

include_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}/src
    ${CMAKE_CURRENT_SOURCE_DIR}/depends
    ${CMAKE_CURRENT_BINARY_DIR}
    ${LLVM_INCLUDE_DIRS}
)

# Create executable

file(GLOB_RECURSE SOURCES CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/src/*.cpp")
file(GLOB_RECURSE DEPENDENCIES CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/depends/*.cpp")

add_executable(compiler
    ${BISON_PARSER_OUTPUTS}
    ${FLEX_LEXER_OUTPUTS}
    ${SOURCES}
    ${DEPENDENCIES}
)

set_target_properties(compiler PROPERTIES
    CXX_STANDARD 17
    CXX_STANDARD_REQUIRED ON
)
target_compile_options(compiler PRIVATE -Wall -Wextra -Wpedantic -Wno-sign-compare)

# Magically link to LLVM
llvm_config(compiler USE_SHARED support core irreader)