testing: Add property tests for subset columns.

Author: mchav

dataframe.cabal

@@ -183,6 +183,7 @@ test-suite tests
     main-is: Main.hs
     other-modules: Assertions,
                    Functions,
+                   GenDataFrame,
                    Operations.Aggregations,
                    Operations.Apply,
                    Operations.Core,
@@ -194,13 +195,15 @@ test-suite tests
                    Operations.Merge,
                    Operations.ReadCsv,
                    Operations.Sort,
+                   Operations.Subset,
                    Operations.Statistics,
                    Operations.Take,
                    Parquet
     build-depends:  base >= 4 && < 5,
                     dataframe ^>= 0.4,
                     directory >= 1.3.0.0 && < 2,
                     HUnit ^>= 1.6,
+                    QuickCheck >= 2 && < 3,
                     random >= 1 && < 2,
                     random-shuffle >= 0.0.4 && < 1,
                     random >= 1 && < 2,

tests/GenDataFrame.hs

@@ -0,0 +1,42 @@
+{-# LANGUAGE GADTs #-}
+{-# LANGUAGE TypeApplications #-}
+
+module GenDataFrame where
+
+import qualified Data.Map as M
+import qualified Data.Text as T
+import qualified Data.Vector as V
+import qualified Data.Vector.Unboxed as VU
+import DataFrame.Internal.Column
+import DataFrame.Internal.DataFrame
+import Test.QuickCheck
+
+genColumn :: Int -> Gen Column
+genColumn len =
+    oneof
+        [ BoxedColumn . V.fromList <$> vectorOf len (arbitrary @Int)
+        , UnboxedColumn . VU.fromList <$> vectorOf len (arbitrary @Double)
+        , OptionalColumn . V.fromList <$> vectorOf len (arbitrary @(Maybe Int))
+        ]
+
+genDataFrame :: Gen DataFrame
+genDataFrame = do
+    numRows <- choose (0, 100)
+    numCols <- choose (0, 10)
+    colNames <- V.fromList <$> vectorOf numCols genUniqueColName
+    cols <- V.fromList <$> vectorOf numCols (genColumn numRows)
+    let indices = M.fromList $ zip (V.toList colNames) [0 ..]
+    pure $
+        DataFrame
+            { columns = cols
+            , columnIndices = indices
+            , dataframeDimensions = (numRows, numCols)
+            , derivingExpressions = M.empty
+            }
+
+genUniqueColName :: Gen T.Text
+genUniqueColName = T.pack <$> listOf1 (elements ['a' .. 'z'])
+
+instance Arbitrary DataFrame where
+    arbitrary = genDataFrame
+    shrink df = []

tests/Main.hs

@@ -1,4 +1,5 @@
 {-# LANGUAGE OverloadedStrings #-}
+{-# LANGUAGE RecordWildCards #-}
 {-# LANGUAGE ScopedTypeVariables #-}
 
 module Main where
@@ -12,7 +13,9 @@ import qualified DataFrame.Operations.Typing as D
 import qualified System.Exit as Exit
 
 import Data.Time
+import GenDataFrame ()
 import Test.HUnit
+import Test.QuickCheck
 
 import qualified Functions
 import qualified Operations.Aggregations
@@ -27,6 +30,7 @@ import qualified Operations.Merge
 import qualified Operations.ReadCsv
 import qualified Operations.Sort
 import qualified Operations.Statistics
+import qualified Operations.Subset
 import qualified Operations.Take
 import qualified Parquet
 
@@ -5105,9 +5109,18 @@ tests =
             ++ Parquet.tests
             ++ parseTests
 
+isSuccessful :: Result -> Bool
+isSuccessful (Success{..}) = True
+isSuccessful _ = False
+
 main :: IO ()
 main = do
     result <- runTestTT tests
-    if failures result > 0 || errors result > 0
+    -- Property tests
+    propRes <-
+        mapM
+            (quickCheckWithResult stdArgs)
+            Operations.Subset.tests
+    if failures result > 0 || errors result > 0 || not (all isSuccessful propRes)
         then Exit.exitFailure
         else Exit.exitSuccess

tests/Operations/Subset.hs

@@ -0,0 +1,95 @@
+{-# LANGUAGE GADTs #-}
+
+module Operations.Subset where
+
+import DataFrame.Internal.DataFrame
+import qualified DataFrame.Operations.Core as D
+import qualified DataFrame.Operations.Subset as D
+import System.Random
+
+prop_dropZero :: DataFrame -> Bool
+prop_dropZero df = D.drop 0 df == df
+
+prop_takeZero :: DataFrame -> Bool
+prop_takeZero df = fst (dataframeDimensions (D.take 0 df)) == 0
+
+prop_takeAll :: DataFrame -> Bool
+prop_takeAll df =
+    let n = fst (dataframeDimensions df)
+     in D.take n df == df
+
+prop_dropAll :: DataFrame -> Bool
+prop_dropAll df =
+    let n = fst (dataframeDimensions df)
+     in fst (dataframeDimensions (D.drop n df)) == 0
+
+prop_takeLastZero :: DataFrame -> Bool
+prop_takeLastZero df = fst (dataframeDimensions (D.takeLast 0 df)) == 0
+
+prop_dropLastZero :: DataFrame -> Bool
+prop_dropLastZero df = D.dropLast 0 df == df
+
+prop_takeLastAll :: DataFrame -> Bool
+prop_takeLastAll df =
+    let n = fst (dataframeDimensions df)
+     in D.takeLast n df == df
+
+prop_dropLastAll :: DataFrame -> Bool
+prop_dropLastAll df =
+    let n = fst (dataframeDimensions df)
+     in fst (dataframeDimensions (D.dropLast n df)) == 0
+
+prop_rangeEmpty :: DataFrame -> Bool
+prop_rangeEmpty df =
+    fst (dataframeDimensions (D.range (5, 5) df)) == 0
+
+prop_rangeFull :: DataFrame -> Bool
+prop_rangeFull df =
+    let rows = fst (dataframeDimensions df)
+     in D.range (0, rows) df == df
+
+prop_selectAll :: DataFrame -> Bool
+prop_selectAll df = D.select (D.columnNames df) df == df
+
+prop_selectEmpty :: DataFrame -> Bool
+prop_selectEmpty df =
+    let result = D.select [] df
+     in dataframeDimensions result == (0, 0)
+
+prop_excludeEmpty :: DataFrame -> Bool
+prop_excludeEmpty df = D.exclude [] df == df
+
+prop_excludeAll :: DataFrame -> Bool
+prop_excludeAll df =
+    let result = D.exclude (D.columnNames df) df
+     in snd (dataframeDimensions result) == 0
+
+prop_cubePreservesSmall :: DataFrame -> Bool
+prop_cubePreservesSmall df =
+    let (rows, cols) = dataframeDimensions df
+     in D.cube (rows + 100, cols + 100) df == df
+
+prop_sampleEmptyApprox :: DataFrame -> Bool
+prop_sampleEmptyApprox df =
+    let gen = mkStdGen 42
+        sampled = D.sample gen 0.0 df
+     in fst (dataframeDimensions sampled) == 0
+
+tests =
+    [ prop_dropZero
+    , prop_takeZero
+    , prop_takeAll
+    , prop_dropAll
+    , prop_takeLastZero
+    , prop_dropLastZero
+    , prop_takeLastAll
+    , prop_dropLastAll
+    , prop_rangeEmpty
+    , prop_rangeFull
+    , prop_selectAll
+    , prop_selectEmpty
+    , prop_excludeEmpty
+    , prop_excludeAll
+    , prop_cubePreservesSmall
+    , prop_sampleEmptyApprox
+    ]