NixOS-Configuration/home/default.nix at master · DXV515/NixOS-Configuration · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
{ self
, pkgs
, lib
, inputs
, hostname
, username
, platform
, stateVersion
, homeModules
, commonModules
, isWorkstation ? false
, wm ? ""
, swayEnable ? false
, hyprlandEnable ? false
, wmEnable ? false
, ...
}:

let
  inherit (pkgs.stdenv) isDarwin;
  inherit (pkgs.stdenv) isLinux;

  isRoot                     = username == "root";
  homeDirectory              = if isDarwin then "/Users/${username}" else if isRoot then "/root" else "/home/${username}";
  userConfigurationPath      = "${self}/home/users/${username}";
  userConfigurationPathExist = builtins.pathExists userConfigurationPath;
  userModulesPath            = "${self}/home/users/${username}/modules";
  userModulesPathExist       = builtins.pathExists userModulesPath;
  sshModulePath              = "${homeModules}/ssh";
  sshModuleExistPath         = builtins.pathExists sshModulePath;
in {
  home-manager = {
    useGlobalPkgs   = true;
    useUserPackages = true;
    backupFileExtension = "backup-" + pkgs.lib.readFile "${pkgs.runCommand "timestamp" {} "echo -n `date '+%Y%m%d%H%M%S'` > $out"}";

    extraSpecialArgs  = {
      inherit
        inputs
        self
        hostname
        username
        platform
        stateVersion
        isLinux
        commonModules
        homeModules
        isWorkstation
        wm
        swayEnable
        hyprlandEnable
        wmEnable;
    };

    users.${username} = {
      imports = [
        inputs.impermanence.nixosModules.home-manager.impermanence
        inputs.sops-nix.homeManagerModules.sops
        inputs.nur.nixosModules.nur

        "${commonModules}"
        "${homeModules}"
      ] ++ lib.optional sshModuleExistPath         sshModulePath
        ++ lib.optional userConfigurationPathExist userConfigurationPath
        ++ lib.optional userModulesPathExist       userModulesPath;

      home = {
        inherit username;
        inherit stateVersion;
        inherit homeDirectory;
      };
    };
  };
}