RavenDictionary/build.gradle at master · CherokeeLanguage/RavenDictionary · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
plugins {
    id "java"
    id "idea"
    id "eclipse"
    id "eclipse-wtp"
    id "com.diffplug.eclipse.apt"
    id 'com.github.johnrengelman.shadow'
}

compileJava.options.encoding = 'UTF-8'
compileJava.options.release = 17

compileTestJava.options.encoding = 'UTF-8'
compileTestJava.options.release = 17

java.toolchain.languageVersion = JavaLanguageVersion.of(17)
java.toolchain.vendor = JvmVendorSpec.ADOPTOPENJDK

jar.manifest.attributes "Main-Class": 'com.cherokeelessons.raven.Main'
shadowJar.archiveFileName = 'RavenDictionary.jar'
shadowJar.mergeServiceFiles()

repositories {
    mavenCentral()
    google()
    maven { url "https://jitpack.io/" }
}

configurations {
    provided
}

dependencies {
    implementation 'org.apache.commons:commons-csv:1.9.0'
    implementation 'org.apache.commons:commons-text:1.9'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.13.3'
    implementation 'commons-io:commons-io:2.11.0'
    implementation 'org.languagetool:language-en:5.8'
    implementation 'org.languagetool:languagetool-core:5.8'
    implementation project(':SimpleTextUi')

    testImplementation 'org.testng:testng:7.6.1'
}

sourceSets {
    main {
        compileClasspath += configurations.provided
    }
    test {
        compileClasspath += configurations.provided
        runtimeClasspath += configurations.provided
    }
}

task "create-dirs" {
    doLast {
        sourceSets*.java.srcDirs*.each { it.mkdirs() }
        sourceSets*.resources.srcDirs*.each { it.mkdirs() }
    }
}

eclipseJdt {
    doLast {
        File f = file('.settings/org.eclipse.core.resources.prefs')
        f.write('eclipse.preferences.version=1\n')
        f.append('encoding/<project>=utf-8')
        f = file('.settings/org.eclipse.core.runtime.prefs')
        f.write('eclipse.preferences.version=1\n')
        f.append('line.separator=\\n\n')
    }
}

// Required for correct setup of APT in Eclipse
eclipseJdt.dependsOn cleanEclipseJdt, eclipseJdtApt
eclipseJdtApt.dependsOn cleanEclipseJdtApt, eclipseFactorypath
eclipseFactorypath.dependsOn cleanEclipseFactorypath, "create-dirs"

eclipse {
    synchronizationTasks eclipseJdt
    project {
        name = 'RavenDictionary'
        comment = 'The Raven Dictionary Project'
    }

    classpath {
        plusConfigurations += [configurations.provided]
        downloadSources = true
        downloadJavadoc = true
    }

    jdt {
    }

    wtp {
        facet {
        }
    }
}

test {
    useTestNG()
}