NextClient/CMakeLists.txt at main · CS-NextClient/NextClient · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
set(CMAKE_TOOLCHAIN_FILE "${CMAKE_CURRENT_SOURCE_DIR}/vcpkg/scripts/buildsystems/vcpkg.cmake" CACHE STRING "Vcpkg toolchain file")
set(VCPKG_TARGET_TRIPLET "x86-windows-static" CACHE STRING "Vcpkg triplet")

cmake_minimum_required(VERSION 3.21)
project(NextClient VERSION 2.5.0)

set(NEXTCLIENT_ROOT ${CMAKE_CURRENT_SOURCE_DIR})

# TODO do fetch curl and zlib via vcpkg, make a custom port if necessary
set(CMAKE_MODULE_PATH
        ${NEXTCLIENT_ROOT}/cmake
        ${CMAKE_MODULE_PATH}
)

set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/out/bin/${CMAKE_BUILD_TYPE})
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY})
set(CMAKE_PDB_OUTPUT_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/out/pdb/${CMAKE_BUILD_TYPE})

# CMAKE_MSVC_RUNTIME_LIBRARY and BUILD_SHARED_LIBS only affect external dependencies.
# NextClient subprojects are always built as shared libraries with mt runtime.
if (VCPKG_TARGET_TRIPLET STREQUAL "x86-windows-static")
    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
else ()
    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL")
endif ()
set(BUILD_SHARED_LIBS OFF)

# NitroApi options
set(NITRO_API_MSVC_RUNTIME_LIBRARY ${CMAKE_MSVC_RUNTIME_LIBRARY})

# cpr options
set(CPR_USE_SYSTEM_CURL ON)
set(CPR_USE_SYSTEM_GTEST OFF)
set(CPR_ENABLE_CURL_HTTP_ONLY OFF)
set(CPR_ENABLE_SSL ON)

# external dependencies
add_subdirectory(dep/cpr)
add_subdirectory(dep/easyloggingpp)
add_subdirectory(dep/bzip2)
add_subdirectory(dep/glad)
add_subdirectory(dep/stb)

# NextClient sub-projects
add_subdirectory(dep/NclNitroApi)
add_subdirectory(nextclient/packages)
add_subdirectory(nextclient/launcher)
add_subdirectory(nextclient/engine_mini)
add_subdirectory(nextclient/filesystem_proxy)
add_subdirectory(nextclient/client_mini)
add_subdirectory(nextclient/gameui)
add_subdirectory(nextclient/steam_api_proxy)

# custom build targets
add_custom_target(BUILD_ALL ALL)
add_dependencies(BUILD_ALL
        next_launcher
        engine_mini
        filesystem_proxy
        client_mini
        gameui
        steam_api_proxy
        nitro_api
        vgui2
)

add_custom_target(INSTALL_ALL
        COMMENT "Installing libraries and assets..."
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:next_launcher> $ENV{NEXTCLIENT_INSTALL_DIR}/cstrike.exe
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:engine_mini> $ENV{NEXTCLIENT_INSTALL_DIR}/next_engine_mini.dll
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:filesystem_proxy> $ENV{NEXTCLIENT_INSTALL_DIR}/FileSystem_Proxy.dll
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:client_mini> $ENV{NEXTCLIENT_INSTALL_DIR}/cstrike/cl_dlls/client_mini.dll
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:gameui> $ENV{NEXTCLIENT_INSTALL_DIR}/cstrike/cl_dlls/GameUI.dll
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:steam_api_proxy> $ENV{NEXTCLIENT_INSTALL_DIR}/steam_api.dll
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:nitro_api> $ENV{NEXTCLIENT_INSTALL_DIR}/nitro_api2.dll
        COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:vgui2> $ENV{NEXTCLIENT_INSTALL_DIR}/vgui2.dll
        COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/dep/optic/bin/OptickCore.dll $ENV{NEXTCLIENT_INSTALL_DIR}/OptickCore.dll
        COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/assets $ENV{NEXTCLIENT_INSTALL_DIR}
)

add_custom_target(BUILD_AND_INSTALL_ALL ALL)
add_dependencies(BUILD_AND_INSTALL_ALL
        BUILD_ALL
        INSTALL_ALL
)

# Add Windows system libraries for HWID collection
target_link_libraries(engine_mini PRIVATE
    crypt32
    advapi32
    wbemuuid
    ole32
    oleaut32
)