jBookFinder/build.gradle at main · BeanVortex/jBookFinder · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
import org.gradle.internal.os.OperatingSystem

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.13'
    id 'org.beryx.jlink' version '2.26.0'
}

group = 'ir.darkdeveloper'
version = '1.1.3'
sourceCompatibility = '19'
targetCompatibility = '19'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}


repositories {
    mavenCentral()
}

application {
    mainClass = 'ir.darkdeveloper.jbookfinder.JBookFinder'
    mainModule = 'ir.darkdeveloper.jbookfinder'
}

javafx {
    version = "19.0.2.1"
    modules = ['javafx.controls', 'javafx.fxml', "javafx.graphics"]
}


dependencies {
    implementation 'org.controlsfx:controlsfx:11.1.2'
    implementation 'commons-io:commons-io:2.11.0'
    implementation 'org.jsoup:jsoup:1.15.3'
    implementation 'org.xerial:sqlite-jdbc:3.40.0.0'
    implementation 'io.projectreactor:reactor-core:3.4.24'
    implementation 'org.projectlombok:lombok:1.18.26'
    annotationProcessor 'org.projectlombok:lombok:1.18.26'
}


tasks.named('test') {
    useJUnitPlatform()
}

jlink {
    imageZip = project.file("${buildDir}/distributions/app-${javafx.platform.classifier}.zip") as RegularFile
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    launcher {
        name = 'JBookFinder'
    }
    jpackage {
        if (OperatingSystem.current().windows) {
            appVersion = version
            installerName = 'JBookFinder'
            installerOptions = ['--win-menu', '--win-shortcut', '--icon', 'src/main/resources/ir/darkdeveloper/jbookfinder/icons/logo.ico']
            imageOptions = ['--icon', 'src/main/resources/ir/darkdeveloper/jbookfinder/icons/logo.ico']
        }
    }
    mergedModule {
        excludeProvides servicePattern: 'reactor.blockhound.*'
    }
}

jlinkZip {
    group = 'distribution'
}