feat(list): adding list:sortByKey

Author: SuperFola

List.ark

@@ -246,6 +246,29 @@
     (set _index (+ 1 _index)) })
   _output }))
 
+# @brief Sort elements in a list using a function to compute the key
+# @details Use the quicksort algorithm, the original list is not modified.
+# @param _L list to sort
+# @param _key function called on each element of the list, returning a unique key to use for sorting
+# =begin
+# (let ranges [[3 5] [10 14] [16 20] [12 18]])
+# (let sorted (sortByKey ranges (fun (e) (head e))))
+# (print sorted)  # [[3 5] [10 14] [12 18] [16 20]]
+# =end
+# @author https://github.com/SuperFola
+(let sortByKey (fun (_L _key) {
+  (if (empty? _L)
+    []
+    {
+      (let _pivot_val (head _L))
+      (let _pivot (_key _pivot_val))
+
+      (mut _less (sortByKey (filter (tail _L) (fun (e) (< (_key e) _pivot))) _key))
+      (let _more (sortByKey (filter (tail _L) (fun (e) (>= (_key e) _pivot))) _key))
+
+      (concat! _less [_pivot_val] _more)
+      _less }) }))
+
 # @brief Apply a given function to each element of a list
 # @param _L the list to work on
 # @param _f the function to apply to each element

tests/list-tests.ark

@@ -5,6 +5,7 @@
 (let a [1 2 3])
 (let b [4 5 6])
 (let zipped [[1 5] [2 6] [3 7] [4 8]])
+(let reversedZipped [[4 8] [3 7] [2 6] [1 5]])
 
 (test:suite list {
     (test:case "builtins" {
@@ -78,6 +79,11 @@
         (test:eq (list:filter a (fun (e) (> e 100))) [])
         (test:eq (list:filter [] (fun (e) (> e 100))) []) })
 
+    (test:case "sortByKey" {
+        (test:eq (list:sortByKey reversedZipped (fun (e) (head e))) zipped)
+        (test:eq (list:sortByKey [9 8 1] (fun (e) e)) [1 8 9])
+        (test:eq (list:sortByKey [] (fun (e) e)) []) })
+
     (test:case "map" {
         (test:eq (list:map b (fun (e) (* e e))) [16 25 36])
         (test:eq (list:map [] (fun (e) (* e e))) []) })