IlwisCore/pythonscript.pro at master · 52North/IlwisCore · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
# Instructions:
#
# First build project "pythonapi" (follow the instructions in pythonapi.pro if not yet done)
# Then build project "pythonscript"

CONFIG += plugin
TARGET = pythonscript

include(global.pri)

DESTDIR = $$PWD/../libraries/$$PLATFORM$$CONF/extensions/$$TARGET
DLLDESTDIR = $$PWD/../output/$$PLATFORM$$CONF/bin/extensions/$$TARGET

TEMPLATE = lib

DEFINES += PYTHONSCRIPT_LIBRARY

SOURCE_RESOURCE = $$clean_path($$PWD/$$TARGET/resources/libraries.config)
TARGET_RESOURCE_DIR = $$clean_path($$PWD/../output/$$PLATFORM$$CONF/bin/extensions/$$TARGET/resources/)
TARGET_RESOURCE = $$TARGET_RESOURCE_DIR/libraries.config
resources.target = $$TARGET_RESOURCE
linux {
    resources.commands = $$quote(test -d $$TARGET_RESOURCE_DIR || mkdir -p $$TARGET_RESOURCE_DIR$$escape_expand(\n\t))
}
win32 {
    SOURCE_RESOURCE = $$replace(SOURCE_RESOURCE,/,\\)
    TARGET_RESOURCE = $$replace(TARGET_RESOURCE,/,\\)
    TARGET_RESOURCE_DIR = $$replace(TARGET_RESOURCE_DIR,/,\\)
    resources.commands = $$quote(if not exist $$TARGET_RESOURCE_DIR mkdir $$TARGET_RESOURCE_DIR$$escape_expand(\n\t))
}
resources.commands += $$quote($(COPY) $$SOURCE_RESOURCE $$TARGET_RESOURCE_DIR$$escape_expand(\n\t))
resources.depends = $$SOURCE_RESOURCE
PRE_TARGETDEPS += $$TARGET_RESOURCE
QMAKE_EXTRA_TARGETS += resources

OTHER_FILES += \
    pythonscript/pythonscript.json \
    pythonscript/resources/libraries.config

LIBS += -L$$PWD/../libraries/$$PLATFORM$$CONF -lilwiscore \
        -L$$PWD/../libraries/$$PLATFORM$$CONF/extensions/pythonapi -lpython35 \
        -L$$PWD/../libraries/$$PLATFORM$$CONF/extensions/pythonapi -l_ilwisobjects

win32:CONFIG(release, debug|release): {
    QMAKE_CXXFLAGS_RELEASE += -O2
}

INCLUDEPATH +=  $$PWD/core \
                $$PWD/../external/python35/include \
                $$PWD/../IlwisConnectors/pythonapi
DEPENDPATH +=   $$PWD/core \
                $$PWD/../external/python35/include

HEADERS += \
    pythonscript/pythonscriptmodule.h \
    pythonscript/runpython.h \
    pythonscript/pythonobjectfactory.h \
    pythonscript/pythonworkflowconnector.h \
    pythonscript/pythonscriptconnector.h \
    pythonscript/pythonscriptcatalogexplorer.h \
    pythonscript/callpythonoperation.h \
    pythonscript/generatescriptnode.h \
    pythonscript/runpythonprogram.h

SOURCES += \
    pythonscript/pythonscriptmodule.cpp \
    pythonscript/runpython.cpp \
    pythonscript/pythonobjectfactory.cpp \
    pythonscript/pythonworkflowconnector.cpp \
    pythonscript/pythonscriptconnector.cpp \
    pythonscript/pythonscriptcatalogexplorer.cpp \
    pythonscript/callpythonoperation.cpp \
    pythonscript/generatescriptnode.cpp \
    pythonscript/runpythonprogram.cpp